Javaバイトコード入門

わかる !Java バイトコード ― 30 分でわからない ?Java バイトコード入門筑波大学大学院システム情報工学研究科　博士後期課程水島宏太

自己紹介とか Twitter: @kmizu はてな : id:kmizushima github: http://github.com/kmizu/ 大学院生構文解析の研究とかやってます特に Packrat Parsing Scala 好き Scala の布教活動をあちこちでやったり JVM 好き JVM 上で動作する言語処理系 Onion を開発

Agenda プログラミング言語としての Java バイトコードマシンモデル型システム命令セットクラスファイルベリファイアベリファイアがはじく操作の例簡単なプログラムを javap で逆アセンブルする役に立つかもしれない javap のオプション解説クラスファイル仕様については省略時間が足りないので…

Javaバイトコードとは Java仮想マシン(JVM)の機械語命令オペコードが1 バイトである事に由来１命令が必ずしも１バイトなわけではない(後述) 特徴：スタックマシンオブジェクト指向的(Java的)な型システム安全でない操作が(基本的に)できないクラスファイルベリファイアによる事前チェック

Hello, World!を逆アセンブルする public class Hello { public static void main(String[] args){ System.out.println("Hello, World!"); } } ↓ public static void main(java.lang.String[]); Code: 0: getstatic #2; //Field java/lang/System.out:Ljava/io/PrintStream; 3: ldc #3; //String Hello, World! 5: invokevirtual #4; //Method java/io/PrintStream.println:(Ljava/lang/String;)V 8: return

Hello, World!を読む 0: getstatic #2; //Field java/lang/System.out:Ljava/io/PrintStream; 0: バイトコード配列の 0 番目を意味している getstatic: オペコードのニーモニック java/lang/System.out: System.out の完全限定名 Ljava/io/PrintStream;: System.out の型 System.out をスタックにロード 3: ldc #3; //String Hello, World! //←1: ではなく 3: である点に注意文字列定数 "Hello, World!" をスタックにロード 5: invokevirtual #4; //Method java/io/PrintStream.println:(Ljava/lang/String;)V PrintStream のメソッド println を呼び出す 8: return メソッドから return する

スタックマシン演算対象( オペランド )がスタックに置かれる ←->レジスタマシンオペランドが置かれるスタック＝オペランドスタックおおざっぱに言って、以下の繰り返し 1. 命令( オペコード )を取り出す 2. オペランドスタックから値をポップ 3. 命令を実行 4. 実行結果をオペランドスタックにプッシュ 5. 1.に戻る

スタックマシンの動作イメージ var pc: int var ops: byte[] ... while(pc < ops.length) { switch(ops[pc]) { case ADD: r = pop; l = pop; push(l + r); case SUB: r = pop; l = pop; push(l - r); case DIV: ... } pc++; }

型システムプリミティブ型 byte, short, int, long, char float, double void boolean 参照型配列型クラス型インタフェース型だいたい Java と同じだけど細かい所が違う

実際の型と計算上の型とカテゴリ演算命令が直接サポートしていない型が存在 byte, short, char, boolean int 型の値として計算されるカテゴリおおざっぱに言うと、オペランドスタック上における値のサイズ boolean, byte, char, short, int, float, 参照型は 1 long, double は 2 命令のオペランドは特定のカテゴリでないと受け付けないものがある

実際の型と計算上の型とカテゴリ 2 double double 2 long long 1 returnAddress returnAddress 1 reference reference 1 float float 1 int int 1 int short 1 int char 1 int byte 1 int boolean カテゴリ計算上の型実際の型

命令の分類大体 Java 仮想マシン仕様第 2 版に沿ってるが、一部独自に分類ロード / ストア命令算術命令型変換命令配列関係の命令オブジェクトの生成・操作制御命令例外のスロー同期化命令メソッド呼び出し関係の命令使われなくなった命令

ロード / ストア命令 (1) – 定数をオペランドスタックにロードする命令 bipush … byte の即値をプッシュ sipush … short の即値をプッシュ iconst_<i> … -1,0,...,5 をプッシュ aconst_null … null をプッシュ ldc, ldc_w, ldc2_w 文字列定数 , 整数 , 浮動小数点数を実行時コンスタントプールからプッシュするなど

bipush byte の即値をプッシュフォーマット： <0x10, byte> オペランドスタック： ... ⇒ ..., value byte の即値が int の value へと符号拡張され、プッシュされる

ldc 実行時コンスタントプールから値をプッシュするフォーマット： <0x18, index> index が示すエントリは、 int 型または float 型の実行時定数か、文字列リテラルへのシンボル参照でなければならないオペランドスタック： ... ⇒ ..., value エントリが int 型または float 型の実行時定数の場合、該当する定数が int 型あるいは float 型としてプッシュされるエントリが文字列リテラルへのシンボル参照の場合、そのインスタンスへの参照がプッシュされる

ロード / ストア命令 (2) – ローカル変数の値をオペランドスタックにロードする iload … ローカル変数から int をロード iload_<n> … ローカル変数から int をロード n = 0 ～ 3 fload … ローカル変数から float をロード fload_<n> … ローカル変数から float をロード n = 0 ～ 3 aload … ローカル変数から参照型の値をロードなど

iload ローカル変数から int をロードするフォーマット： <0x15,index> オペランドスタック： ..., ⇒ ..., value index 番目のローカル変数の値がスタックにプッシュされる index 番目のローカル変数には int 型の値が保持されていなければならない

fload ローカル変数から float をロードするフォーマット： <0x17,index> オペランドスタック： ..., ⇒ ..., value index 番目のローカル変数の値がスタックにプッシュされる index 番目のローカル変数には float 型の値が保持されていなければならない

ロード / ストア命令 (3) – 値をローカル変数にストアする istore … ローカル変数に int をストア istore_<n> … ローカル変数から int をロード n = 0 ～ 3 fstore … ローカル変数に float をストア fstore_<n> … ローカルに float をストア n = 0 ～ 3 astore … ローカル変数に参照型の値をストアなど

istore ローカル変数に int をストアするフォーマット： <0x36,index> オペランドスタック： ..., value ⇒ ..., スタックトップの値が、 index 番目のローカル変数にストアされるスタックトップの値は int 型でなければならない

fstore ローカル変数に float をストアするフォーマット： <0x38,index> オペランドスタック： ..., value ⇒ ..., スタックトップの値が、 index 番目のローカル変数にストアされるスタックトップの値は float 型でなければならない

算術命令 iadd, ladd, fadd, dadd … 加算 isub, lsub, fsub, dsub … 減算 imul, lmul, fmul, dmul … 乗算 idiv, ldiv, fdiv, ddiv … 除算 irem, lrem, frem, drem … 剰余 ineg, lneg, fneg, dneg … 符号反転など

iadd int の加算を行うフォーマット： <0x60> オペランドスタック： ..., value1, value2 ⇒ ..., result value1 + value2 の結果がスタックにプッシュされる value1 と value2 は int 型でなければならない

lsub long の加算を行うフォーマット： <0x65> オペランドスタック： ..., value1, value2 ⇒ ..., result value1 - value2 の結果がスタックにプッシュされる value1 と value2 は long 型でなければならない

型変換命令ワイドニング数値変換命令 i2l … int から long への型変換を行う i2f … int から float への型変換を行う … ナローイング数値変換命令 i2b … int から byte への変換を行う i2c … int から char への変換を行う …

i2l int を long に変換するフォーマット： <0x85> オペランドスタック： ..., value ⇒ ..., result value が long へと符号拡張された結果がプッシュされる value は int 型でなければならない

i2b int を byte に変換するフォーマット： <0x91> オペランドスタック： ..., value ⇒ ..., result value が byte へ切り捨てられ、 int へと符号拡張された結果がプッシュされる value は int 型でなければならない

配列関係の命令配列を生成する命令 newarray … 1 次元配列を生成する … 配列の要素をロードする命令 baload … byte 型の配列要素をロードする … 配列の要素に値をストアする命令 bastore … byte 型の配列要素に値をストアする … arraylength … 配列の長さを取得する

newarray 配列を生成するフォーマット： <0xbc,atype> atype は生成する配列の型 ( プリミティブ型 ) を表したコード 4,5,6,7,8,9,10,11 のいずれかオペランドスタック： ..., count ⇒ ..., objectref count は int 型でなければならない要素型が atype で長さが count の配列が生成されて、配列への参照がプッシュされる

arraylength 配列の長さを取得するフォーマット： <0xbe> オペランドスタック： ..., arrayref ⇒ ..., length arrayref は配列への参照でなければならない arrayref が参照する配列の長さがスタックにプッシュされる

オブジェクトの生成・操作 new … オブジェクトを生成 getfield … フィールドを取得 putfield … フィールドに値をストア getstatic … static フィールドを取得 putstatic … static フィールドに値をストア instanceof … Java の instanceof 相当 checkcast … 参照型のキャストを行う

new オブジェクトを生成するフォーマット： <0xbb,indexbyte1,indexbyte2> indexbyte はクラス型へのシンボル参照でなければならないオペランドスタック： ..., ⇒ ..., objectref 指定された型のオブジェクトが生成されて、スタックにプッシュされる

getstatic static フィールドを取得するフォーマット： <0xb2,indexbyte1,indexbyte2> indexbyte は該当するフィールドへのシンボル参照でなければならないオペランドスタック： ..., ⇒ ..., value static フィールドの値がスタックにプッシュされる

スタック管理命令スタック上の値の順番を入れ替えたりする pop, pop2 … スタックから値をポップする dup, dup2 … スタックトップの値を複製 dup_x1 … スタックトップの値を複製して、トップの二つ下の値として挿入 dup_x2 …

pop スタックトップの値をポップするフォーマット： <0x57> オペランドスタック： ..., value ⇒ ... スタックトップの値がカテゴリ 1 の場合のみ使用可

dup スタックトップの値を複製するフォーマット： <0x59> オペランドスタック： ..., value ⇒ ..., value, value スタックトップの値がカテゴリ 1 の場合のみ使用可

制御命令条件分岐命令 ifeq, iflt, ifne, ifgt, ifge, ... 複合条件分岐命令 tableswitch, lookupswitch switch 文に対応無条件分岐命令 goto, goto_w, jsr, jsr_w, ret

goto 無条件ジャンプを行うフォーマット： <0xa7,branchbyte1,branchbyte2> branchbyte(1|2) から、分岐オフセットが生成されるオペランドスタック： ... ⇒ ...

ifeq スタックトップと 0 が等しい場合に該当アドレスにジャンプする成功しない場合、次の命令があるアドレスから実行が再開フォーマット： <0x99,branchbyte1,branchbyte2> branchbyte(1|2) から、分岐オフセットが生成されるオペランドスタック： ..., value ⇒ ...

例外のスロー athrow … 例外を投げる命令 Java の throw 文に相当

athrow 例外を throw する適合するハンドラが見つかるまでメソッドを巻き戻る throw された例外フォーマット： <0xbf> オペランドスタック： ..., objectref ⇒ objectref ハンドラにジャンプする際に、現在のオペランドスタックがクリアされるハンドラにジャンプする際に、 throw された例外オブジェクトへの参照がプッシュされる

同期化命令要は synchronized 文を実装するための命令 monitorenter … モニタに入る monitorexit … モニタから抜ける monitor(enter/exit) を対応させるのはコンパイラ (javac など ) の責任ベリファイアはチェックしない例外や break/continue などで synchronized を抜けるときにもちゃんと対応する箇所で monitorexit を生成してあげないといけない…

メソッド呼び出し関係の命令 invokestatic … static メソッド呼び出し invokespecial … コンストラクタ ( 等 ) 呼び出し invokevirtual … インスタンスメソッド呼び出し invokeinterface … インタフェースのメソッド呼び出し ireturn, lreturn, freturn, dreturn, areturn, return … メソッドからの return

invokestatic static メソッドを呼び出すフォーマット： <0xb8,indexbyte1,indexbyte2> indexbyte は、メソッドへのシンボル参照がある実行時コンスタントプールへのインデックスオペランドスタック： ..., arg1, arg2, ..., arg n ⇒ ... arg1, arg2, ... が引数メソッドの返り値の型に応じて結果がスタックにプッシュされる

invokevirtual インスタンスメソッドを呼び出すフォーマット： <0xb6,indexbyte1,indexbyte2> indexbyte は、メソッドへのシンボル参照がある実行時コンスタントプールへのインデックスオペランドスタック： ..., objectref, arg1, arg2, ..., arg n ⇒ ... objectref はオブジェクトへの参照 arg1, arg2, ... が引数メソッドの返り値の型に応じて結果がスタックにプッシュされる interface 型の参照に対しては使えない点に注意 invokeinterface を使う

使われなくなった命令 jsr, ret … 元々は finally の実装に使われていた JDK 1.4.2 から使われなくなったベリファイア絡みで不具合があることが判明したため http://bugs.sun.com/bugdatabase/view_bug.do?bug_id=4381996 finally は code duplication によって実装されるように変更

クラスファイルベリファイアクラスファイル (.class) のフォーマットが Java 仮想マシン仕様に従っているかどうかを該当クラスの初期化より前にチェックたとえば：同じ pc におけるオペランド・スタックのサイズは常に一定でなければならないオペランド・スタックのオーバーフローやアンダーフローは原理的に発生しない存在しないローカル変数に対するアクセスは無い未初期化のローカル変数に対するアクセスは無い

jasmin 用のプログラム jasmin: Java バイトコードアセンブラ >java Overflow Exception in thread "main" java.lang.VerifyError : (class: Overflow, method: main signature: ([Ljava/lang/String;)V) Inconsistent stack height 1 != 0 ベリファイアがはねるプログラム (1) – スタックオーバーフロー .class public Overflow .super java/lang/Object .method public static main([Ljava/lang/String;)V .limit stack 2 LABEL: ldc "Hello, World!" goto LABEL return .end method

>java Uninitialized Exception in thread "main" java.lang.VerifyError : (class: Uninitialized, method: main signature: ([L java/lang/String;)V) Accessing value from uninitialized register 1 ベリファイアがはねるプログラム (2) – 未初期化ローカル変数へのアクセス .class public Uninitialized .super java/lang/Object .method public static main([Ljava/lang/String;)V .limit stack 2 .limit locals 3 iload_1 return .end method

>java Incompatible Exception in thread "main" java.lang.VerifyError : (class: Incompatible, method: main signature: ([Lj ava/lang/String;)V) Expecting to find integer on stack ベリファイアがはねるプログラム (3) - 型エラー .class public Incompatible .super java/lang/Object .method public static main([Ljava/lang/String;)V .limit stack 2 ldc 3.5 ldc 4.0 iadd return .end method

>java PopLong Exception in thread "main" java.lang.VerifyError : (class: PopLong, method: main signature: ([Ljava/lang/String;)V) Attempt to split long or double on the stack ベリファイアがはねるプログラム (4) - カテゴリ間違い .class public PopLong .super java/lang/Object .method public static main([Ljava/lang/String;)V .limit stack 3 invokestatic java/lang/System/currentTimeMillis()J pop ; pop2 なら OK ． pop はカテゴリ 1 の値しか pop できないが long はカテゴリ 2 return .end method

練習問題 ↓ のコンパイル結果を逆アセンブルしたものを読んでみる ',' で区切られた項目 ( 整数 ) の合計値を計算 import java.util.Scanner; public class CalcSum { public static void main(String[] args) { Scanner scanner = new Scanner(System.in); while(scanner.hasNext()) { int result = 0; String[] line = scanner.nextLine().split(","); for(String element:line) result += Integer.parseInt(element); System.out.println("result:" + result); } } }

練習問題逆アセンブル (javap –c CalcSum) した結果 public class CalcSum { ↓ Compiled from "CalcSum.java" public class CalcSum extends java.lang.Object{ public CalcSum(); Code: 0: aload_0 1: invokespecial #1; //Method java/lang/Object."<init>":()V 4: return

練習問題逆アセンブル (javap –c CalcSum) した結果 public static void main(String[] args) { Scanner scanner = new Scanner(System.in); ↓ public static void main(java.lang.String[]); Code: 0: new #2; //class java/util/Scanner 3: dup 4: getstatic #3; //Field java/lang/System.in:Ljava/io/InputStream; 7: invokespecial #4; //Method java/util/Scanner."<init>":(Ljava/io/InputStream;)V 10: astore_1

練習問題逆アセンブル (javap –c CalcSum) した結果 while(scanner.hasNext()) { ↓ 11: aload_1 12: invokevirtual #5; //Method java/util/Scanner.hasNext:()Z 15: ifeq 97

練習問題逆アセンブル (javap –c CalcSum) した結果 int result = 0; String[] line = scanner.nextLine().split(","); ↓ 18: iconst_0 19: istore_2 20: aload_1 21: invokevirtual #6; //Method java/util/Scanner.nextLine:()Ljava/lang/String; 24: ldc #7; //String , 26: invokevirtual #8; //Method java/lang/String.split:(Ljava/lang/String;)[Ljava/lang/String; 29: astore_3 30: aload_3 31: astore 4

練習問題逆アセンブル (javap –c CalcSum) した結果 for(String element:line) result += Integer.parseInt(element); ↓ 33: aload 4 35: arraylength 36: istore 5 38: iconst_0 39: istore 6 41: iload 6 43: iload 5 45: if_icmpge 69 48: aload 4 50: iload 6 52: aaload 53: astore 7 55: iload_2 56: aload 7 58: invokestatic #9; //Method java/lang/Integer.parseInt:(Ljava/lang/String;)I 61: iadd 62: istore_2 63: iinc 6, 1 66: goto 41

練習問題逆アセンブル (javap –c CalcSum) した結果 System.out.println("result:" + result); } } } ↓ 69: getstatic #10; //Field java/lang/System.out:Ljava/io/PrintStream; 72: new #11; //class java/lang/StringBuilder 75: dup 76: invokespecial #12; //Method java/lang/StringBuilder."<init>":()V 79: ldc #13; //String result: 81: invokevirtual #14; //Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder; 84: iload_2 85: invokevirtual #15; //Method java/lang/StringBuilder.append:(I)Ljava/lang/StringBuilder; 88: invokevirtual #16; //Method java/lang/StringBuilder.toString:()Ljava/lang/String; 91: invokevirtual #17; //Method java/io/PrintStream.println:(Ljava/lang/String;)V 94: goto 11 97: return }

知っていると役に立つ ( かもしれない )javap のオプション -c: 逆アセンブルする。一番よく使う -private: private なものを含む全てのメンバを表示 -c などと組み合わせて使う事が多い -verbose: クラスファイルのバージョン、コンスタントプールなどの詳細な情報を表示 -s: 内部的な型シグネチャの情報を表示 public static void main(java.lang.String[]) -> ([Ljava/lang/String;)V

何が嬉しいの？ Java バイトコードにコンパイルする俺言語 / フレームワーク等を作れるようになるバイトコード変換を利用したツールやフレームワークを作れるようになる AOP とかバイトコードにコンパイルする言語処理系やツールのバグなどを発見できるようになる発表者は、 scala が生成したコードをよく javap している面白い

まとめ Java バイトコードのマシンモデル命令セット型システムについて簡単に解説クラスファイルベリファイアの概要を説明簡単なサンプルコードを逆アセンブルしてみた知っていると役に立つかもしれない javap オプション参考文献： Java 仮想マシン仕様第２版，ティム・リンドホルム、フランク・イェリン，ピアソン・エデュケーション Web で無料公開 http://java.sun.com/docs/books/jvms/second_edition/html/VMSpecTOC.doc.html されてるので、そちらでも可 ( ただし英語 )

Javaバイトコード入門

Recommended

More Related Content

What's hot (20)

Viewers also liked (20)

Similar to Javaバイトコード入門 (8)

More from Kota Mizushima (20)

Javaバイトコード入門