Fix bootstrap parser so that its keywords are unreserved words.

Mark Dilger pointed out that the bootstrap parser does not allow
any of its keywords to appear as column values unless they're quoted,
and proposed dealing with that by quoting such values in genbki.pl.
Looking closer, though, we also have that problem with respect to table,
column, and type names appearing in the .bki file: the parser would fail
if any of those matched any of its keywords.  While so far there have
been no conflicts (that I've heard of), this seems like a booby trap
waiting to catch somebody.  Rather than clutter genbki.pl with enough
quoting logic to handle all that, let's make the bootstrap parser grow
up a little bit and treat its keywords as unreserved.

Experimentation shows that it's fairly easy to do so with the exception
of _null_, which I don't have a big problem with keeping as a reserved
word.  The only change needed is that we can't have the "close" command
take an optional table name: it has to either require or forbid the
table name to avoid shift/reduce conflicts.  genbki.pl has historically
always included the table name, so I took that option.

The implementation has bootscanner.l passing forward the string value
of each keyword, in case bootparse.y needs that.  This avoids needing to
know the precise spelling of each keyword in bootparse.y, which is good
because that's not always obvious from the token name.

Discussion: https://postgr.es/m/3024FC91-DB6D-4732-B31C-DF772DF039A0@gmail.com

Author: tglsfdc

doc/src/sgml/bki.sgml

@@ -248,6 +248,8 @@
     <listitem>
      <para>
       Null values are represented by <literal>_null_</literal>.
+      (Note that there is no way to create a value that is just that
+      string.)
      </para>
     </listitem>
 
@@ -752,13 +754,13 @@ $ perl  rewrite_dat_with_prokind.pl  pg_proc.dat
 
    <varlistentry>
     <term>
-     <literal>close</literal> <optional><replaceable class="parameter">tablename</replaceable></optional>
+     <literal>close</literal> <replaceable class="parameter">tablename</replaceable>
     </term>
 
     <listitem>
      <para>
-      Close the open table.  The name of the table can be given as a
-      cross-check, but this is not required.
+      Close the open table.  The name of the table must be given as a
+      cross-check.
      </para>
     </listitem>
    </varlistentry>
@@ -782,8 +784,8 @@ $ perl  rewrite_dat_with_prokind.pl  pg_proc.dat
 
      <para>
       NULL values can be specified using the special key word
-      <literal>_null_</literal>.  Values containing spaces must be
-      double quoted.
+      <literal>_null_</literal>.  Values that do not look like
+      identifiers or digit strings must be double quoted.
      </para>
     </listitem>
    </varlistentry>

src/backend/bootstrap/bootparse.y

@@ -105,6 +105,7 @@ static int num_columns_read = 0;
 	List		*list;
 	IndexElem	*ielem;
 	char		*str;
+	const char	*kw;
 	int			ival;
 	Oid			oidval;
 }
@@ -116,17 +117,17 @@ static int num_columns_read = 0;
 %type <oidval> oidspec optoideq optrowtypeoid
 
 %token <str> ID
-%token OPEN XCLOSE XCREATE INSERT_TUPLE
-%token XDECLARE INDEX ON USING XBUILD INDICES UNIQUE XTOAST
 %token COMMA EQUALS LPAREN RPAREN
-%token OBJ_ID XBOOTSTRAP XSHARED_RELATION XWITHOUT_OIDS XROWTYPE_OID NULLVAL
-%token XFORCE XNOT XNULL
+/* NULLVAL is a reserved keyword */
+%token NULLVAL
+/* All the rest are unreserved, and should be handled in boot_ident! */
+%token <kw> OPEN XCLOSE XCREATE INSERT_TUPLE
+%token <kw> XDECLARE INDEX ON USING XBUILD INDICES UNIQUE XTOAST
+%token <kw> OBJ_ID XBOOTSTRAP XSHARED_RELATION XWITHOUT_OIDS XROWTYPE_OID
+%token <kw> XFORCE XNOT XNULL
 
 %start TopLevel
 
-%nonassoc low
-%nonassoc high
-
 %%
 
 TopLevel:
@@ -160,18 +161,12 @@ Boot_OpenStmt:
 		;
 
 Boot_CloseStmt:
-		  XCLOSE boot_ident %prec low
+		  XCLOSE boot_ident
 				{
 					do_start();
 					closerel($2);
 					do_end();
 				}
-		| XCLOSE %prec high
-				{
-					do_start();
-					closerel(NULL);
-					do_end();
-				}
 		;
 
 Boot_CreateStmt:
@@ -489,8 +484,28 @@ boot_column_val:
 			{ InsertOneNull(num_columns_read++); }
 		;
 
-boot_ident :
-		  ID	{ $$ = yylval.str; }
+boot_ident:
+		  ID			{ $$ = $1; }
+		| OPEN			{ $$ = pstrdup($1); }
+		| XCLOSE		{ $$ = pstrdup($1); }
+		| XCREATE		{ $$ = pstrdup($1); }
+		| INSERT_TUPLE	{ $$ = pstrdup($1); }
+		| XDECLARE		{ $$ = pstrdup($1); }
+		| INDEX			{ $$ = pstrdup($1); }
+		| ON			{ $$ = pstrdup($1); }
+		| USING			{ $$ = pstrdup($1); }
+		| XBUILD		{ $$ = pstrdup($1); }
+		| INDICES		{ $$ = pstrdup($1); }
+		| UNIQUE		{ $$ = pstrdup($1); }
+		| XTOAST		{ $$ = pstrdup($1); }
+		| OBJ_ID		{ $$ = pstrdup($1); }
+		| XBOOTSTRAP	{ $$ = pstrdup($1); }
+		| XSHARED_RELATION	{ $$ = pstrdup($1); }
+		| XWITHOUT_OIDS	{ $$ = pstrdup($1); }
+		| XROWTYPE_OID	{ $$ = pstrdup($1); }
+		| XFORCE		{ $$ = pstrdup($1); }
+		| XNOT			{ $$ = pstrdup($1); }
+		| XNULL			{ $$ = pstrdup($1); }
 		;
 %%
 

src/backend/bootstrap/bootscanner.l

@@ -68,64 +68,74 @@ static int	yyline = 1;			/* line number for error reporting */
 id		[-A-Za-z0-9_]+
 sid		\"([^\"])*\"
 
+/*
+ * Keyword tokens return the keyword text (as a constant string) in yylval.kw,
+ * just in case that's needed because we want to treat the keyword as an
+ * unreserved identifier.  Note that _null_ is not treated as a keyword
+ * for this purpose; it's the one "reserved word" in the bootstrap syntax.
+ *
+ * Notice that all the keywords are case-sensitive, and for historical
+ * reasons some must be upper case.
+ *
+ * String tokens return a palloc'd string in yylval.str.
+ */
+
 %%
 
-open			{ return OPEN; }
+open			{ yylval.kw = "open"; return OPEN; }
 
-close			{ return XCLOSE; }
+close			{ yylval.kw = "close"; return XCLOSE; }
 
-create			{ return XCREATE; }
+create			{ yylval.kw = "create"; return XCREATE; }
 
-OID				{ return OBJ_ID; }
-bootstrap		{ return XBOOTSTRAP; }
-"shared_relation"	{ return XSHARED_RELATION; }
-"without_oids"	{ return XWITHOUT_OIDS; }
-"rowtype_oid"	{ return XROWTYPE_OID; }
-_null_			{ return NULLVAL; }
+OID				{ yylval.kw = "OID"; return OBJ_ID; }
+bootstrap		{ yylval.kw = "bootstrap"; return XBOOTSTRAP; }
+shared_relation	{ yylval.kw = "shared_relation"; return XSHARED_RELATION; }
+without_oids	{ yylval.kw = "without_oids"; return XWITHOUT_OIDS; }
+rowtype_oid		{ yylval.kw = "rowtype_oid"; return XROWTYPE_OID; }
+
+insert			{ yylval.kw = "insert"; return INSERT_TUPLE; }
 
-insert			{ return INSERT_TUPLE; }
+_null_			{ return NULLVAL; }
 
 ","				{ return COMMA; }
 "="				{ return EQUALS; }
 "("				{ return LPAREN; }
 ")"				{ return RPAREN; }
 
 [\n]			{ yyline++; }
-[\t]			;
-" "				;
-
-^\#[^\n]* ; /* drop everything after "#" for comments */
-
-
-"declare"		{ return XDECLARE; }
-"build"			{ return XBUILD; }
-"indices"		{ return INDICES; }
-"unique"		{ return UNIQUE; }
-"index"			{ return INDEX; }
-"on"			{ return ON; }
-"using"			{ return USING; }
-"toast"			{ return XTOAST; }
-"FORCE"			{ return XFORCE; }
-"NOT"			{ return XNOT; }
-"NULL"			{ return XNULL; }
+[\r\t ]			;
+
+^\#[^\n]* 		;		/* drop everything after "#" for comments */
+
+declare			{ yylval.kw = "declare"; return XDECLARE; }
+build			{ yylval.kw = "build"; return XBUILD; }
+indices			{ yylval.kw = "indices"; return INDICES; }
+unique			{ yylval.kw = "unique"; return UNIQUE; }
+index			{ yylval.kw = "index"; return INDEX; }
+on				{ yylval.kw = "on"; return ON; }
+using			{ yylval.kw = "using"; return USING; }
+toast			{ yylval.kw = "toast"; return XTOAST; }
+FORCE			{ yylval.kw = "FORCE"; return XFORCE; }
+NOT				{ yylval.kw = "NOT"; return XNOT; }
+NULL			{ yylval.kw = "NULL"; return XNULL; }
 
 {id}			{
 					yylval.str = scanstr(yytext);
 					return ID;
 				}
 {sid}			{
-					yytext[strlen(yytext)-1] = '\0'; /* strip off quotes */
+					/* leading and trailing quotes are not passed to scanstr */
+					yytext[strlen(yytext) - 1] = '\0';
 					yylval.str = scanstr(yytext+1);
-					yytext[strlen(yytext)] = '"'; /* restore quotes */
+					yytext[strlen(yytext)] = '"';	/* restore yytext */
 					return ID;
 				}
 
 .				{
 					elog(ERROR, "syntax error at line %d: unexpected character \"%s\"", yyline, yytext);
 				}
 
-
-
 %%
 
 /* LCOV_EXCL_STOP */