Excelで空白行を削除するマクロは？

VBAの質問としてお受けします。

＞ステートメントが分かる方が要らしたら教えてください
まず、最初に、VBAでは、ステートメントというのは別の意味です。

＞しかし、マウスやキーに依るメニューでは「空白行の削除」と言うのが有りません。
マウスのメニューに加えるということでしょうか？
以下は、その行の全てのセルが空白の場合にのみ、削除されます。

'標準モジュールへ
Sub BlankRowsDelete()
　Dim Rng As Range
　Dim i As Long
　Set Rng = Selection '最初にマウスで範囲を選択
　For i = Rng.Rows.Count To 1 Step -1
　　With Rng.Cells(i, 1)
　　　If Application.CountA(.EntireRow) = 0 Then
　　　　.EntireRow.Delete
　　　End If
　　End With
　Next i
End Sub

'標準モジュールか、ThisWorkbook へ
Sub MouseRightClickMenuAdd()
On Error Resume Next
　Application.CommandBars("CELL").Controls("ブランク行削除").Delete
On Error GoTo 0
　With Application.CommandBars("CELL").Controls.Add _
　(Type:=msoControlButton, Temporary:=True)
　.BeginGroup = True
　.Caption = "ブランク行削除"
　.OnAction = "BlankRowsDelete"
　End With
End Sub

'ThisWorkbookへ
Private Sub Workbook_Open()
Call MouseRightClickMenuAdd
End Sub

なお、右クリックメニューでトラブルがあった時は、
　Application.CommandBars("CELL").Reset
を実行してください。通常、Excelを終了すれば、右クリックメニューは解除されます。

こんばんは。

Wendy02さんの方法が一般的な方法だと思いますが、
もし、Ａ列が空白の行を削除してもよければ、以下のコードでもＯＫです。

--------------------------------------------
Sub TestDelete()

　With Range("A1:A" & Range("A65536").End(xlUp).Row)

　　.SpecialCells(xlCellTypeBlanks).EntireRow.Delete

　End With

End Sub
----------------------------------------------

以上です。

データのレイアウトがわかりませんが、もしも、ある列が空白の行は空白行として

みなしてよいのでしたら、その列全体を選択して、[Ctrl]を押しながら[G]を押し
ます。
ジャンプボックスが表示されますので、[セル選択]から「空白セル」を選択して
ＯＫします。
空白セルがまとめて選択されますので、[編集]-[削除]の「行全体」を指定します。

実際にご使用中のシートの状態が不明なのですが、もしかたしたら、この方法でいけるかもしれません。

うまくすると、マクロを作らなくても空白行を削除できますよ。

１．A列に空白列を追加する
２．A列の1行目から最終行まで、連番を振る(1, 2, 3…）
３．データの入っている列をキーとして、データの並べ替えをする。すると、空白行がソートされてひとまとまりになります。
４．空白行を消す
５．今度はA列をキーとして、データの並べかえをする。するともとの順に戻ります。空白行だけ抜けている状態です。
６．A列を削除する。 以上です。