SAS Macro Programming Made Easy, Third Edition

Part 1: Understanding the Concepts and Features of Macro Programming

Chapter 1 Introduction

What Is the SAS Macro Facility?

What Are the Advantages of the SAS Macro Facility?

Where Can the SAS Macro Facility Be Used?

Examples of the SAS Macro Facility

Imagine you have an assistant who helps you write your SAS programs. Your assistant willingly and unfailingly follows your instructions allowing you to move on to other tasks. Repetitive programming assignments like multiple PROC TABULATE tables, where the only difference between one table and the next is the classification variable, are delegated to your assistant. Jobs that require you to run a few steps, review the output, and then run additional steps based on the output are not difficult; they are, however, time-consuming. With instructions on selection of subsequent steps, your assistant easily handles the work. Even having your assistant do simple tasks like editing information in TITLE statements makes your job easier.

Actually, you already have a SAS programming assistant: the SAS macro facility. The SAS macro facility can do all the tasks above and more. To have the macro facility work for you, you first need to know how to communicate with the macro facility. That's the purpose of this book: to show you how to communicate with the SAS macro facility so that your SAS programming can become more effective and efficient.

An infinite variety of applications of the SAS macro facility exist. An understanding of the SAS macro facility gives you confidence to appropriately use it to help you build your SAS programs. The more you use the macro facility, the more adept you become at using it. As your skills increase, you discover more situations where the macro facility can be applied. The macro programming skills you learn from this book can be applied throughout SAS.

You do not have to use any of the macro facility features to write good SAS programs, but, if you do, you might find it easier to complete your SAS programming assignments. The SAS programming language can get you from one floor to the next, one step after another. Using the macro facility wisely is like taking an elevator to get to a higher floor: you follow the same path, but you'll likely arrive at your destination sooner.

What Is the SAS Macro Facility?

Fundamentally, the SAS macro facility is a tool for text substitution. You associate a macro reference with text. When the macro processor encounters that reference, it replaces the reference with the associated text. This text can be as simple as text strings or as complex as SAS language statements. The macro processor becomes your SAS programming assistant in helping you construct your SAS programs.

The SAS macro facility is a component of Base SAS. The Base SAS product is integral to SAS and must be installed if you want to write SAS programs or run SAS procedures in any of the SAS products. Therefore, if you have access to SAS, you have access to the macro facility, and you can include macro facility features in your programs. Additionally, if you use SAS Enterprise Guide, you can add macro facility features when specifying projects and tasks. Indeed, many of the SAS products that you license contain programs that make use of the macro facility.

As shown in Figure 1.1, the SAS macro facility works side-by-side with Base SAS to build and execute your programs. The macro facility has its own language distinct from the SAS language, but the language and conventions of the macro facility are similar to the style and syntax of the SAS language. If you already write DATA steps, you have a head start on understanding the language and conventions of the macro facility.

Figure 1.1 How the SAS macro facility fits into SAS

The two main components of the SAS macro facility are SAS macro variables and SAS macro programs. With SAS macro variables, you create references to larger pieces of text. A typical use of a macro variable is to repeatedly insert a piece of text throughout a SAS program. SAS macro programs use macro variables and macro programming statements to build SAS programs. Macro programs can direct conditional execution of DATA steps and PROC steps. Macro programs can do repetitive tasks such as creating or analyzing a series of data sets.

Example 1.1 shows how a macro variable can be used, and Example 1.2 shows how a macro program can be used.

Example 1.1: Using a Macro Variable to Select Observations to Process

The macro variable MONTH_SOLD defined in Example 1.1 is used to select a subset of a data set and to place information in the PROC PRINT report title. Macro language and macro variable references are in bold.

%let month_sold=4;

proc print data=books.ytdsales

                   (where=(month(datesold)=&month_sold));

  title "Books Sold for Month &month_sold";

  var booktitle saleprice;

  sum saleprice;

run;

Example 1.2: Using a Macro Program to Execute the Same PROC Step on Multiple Data Sets

When Example 1.2 executes, it submits a PROC MEANS step three times: once for each of the years 2014, 2015, and 2016. Each time, PROC MEANS processes a different data set. The macro language and references that generate the three steps are in bold.

%macro sales;

%do year=2014 %to 2016;

    proc means data=books.sold&year;

      title "Sales Information for &year";

      class section;

      var listprice saleprice;

    run;

%end;

%mend sales;

%sales

SAS first released the macro facility in SAS 82.0 in 1982. SAS macro language has relatively few statements, and these statements are very powerful.

In a world of rapidly changing software tools and techniques, the macro facility remains one of the most widely used and versatile components of SAS. What you learn now about the macro facility will serve you for many years of SAS programming.

What Are the Advantages of the SAS Macro Facility?

Your SAS programming productivity can improve when you know how and when to use the SAS macro facility. The programs you write can become reusable, shorter, and easier to follow.

In addition, when you incorporate macro facility features in your programs you can

• accomplish repetitive tasks quickly and efficiently. A macro program can be reused many times. Parameters passed to the macro program customize the results without having to change the code within the macro program.

• provide a more modular structure to your programs. SAS language that is repetitive can be generated by macro language statements in a macro program, and your SAS program can reference that macro program. The reference to the macro program is similar to calling a subroutine. Your main program becomes easier to read—especially if you give the macro program a meaningful name for the function that it performs.

Think about automated bill paying as a real-world example of the concepts of macro programming. When you enroll in an automated bill paying plan, you no longer initiate payments each month to pay recurring bills like the mortgage and the utilities. Without automated bill paying, it takes a certain amount of time each month for you to initiate payments to pay those recurring bills. The time that it takes to initiate the automated bill paying plan is likely longer in the month that you set it up than if you just submitted a payment for a monthly bill. But, once you have the automated bill paying plan established (and perhaps allowing the bank a little debugging time!), the amount of time you spend each month dealing with those recurring bills is reduced. You instruct your bank how to handle those recurring bills. In turn, the bank initiates those monthly payments for you.

That’s what macro programming can do for you. Instead of editing the program each time parameters change (for example, same analysis program, different data set), you write a SAS program that contains macro language statements. These macro language statements instruct the macro processor how to make those code changes for you. Then, when you run the program again, the only changes you make are to the values that the macro language uses to edit your program–like directing the bank to add the water utility to your automatic payment plan.

Example 1.3: Defining and Using Macro Variables

Consider another illustration of macro programming, this time including a sample program. The data set that is analyzed here is used throughout this book. The data represent computer book sales at a fictitious retailer.

Example 1.3 produces two reports for the computing-related book sales. The first is a monthly sales report. The second is a panel chart of sales from the beginning of the year through the month of interest.

If you were not using macro facility features, you would have to change the program every time you wanted the report for a different month and/or year. These changes would have to be made at every location where the month value and/or year value were referenced.

Rather than doing these multiple edits, you can create macro variables at the beginning of the program that are set to the month and the year of interest and place references to these macro variables throughout the program where they are needed. When you get ready to submit the program, the only changes you make are to the values of the macro variables. After you submit the program, the macro processor looks up the values of month and year that you set and substitutes those values as specified by your macro variable references.

You don't edit the DATA step and the PROC steps; you only change the values of the macro variables at the beginning of the program. The report layout stays the same, but the results are based on a different subset of the data set.

Don't worry about understanding the macro language coding at this point. Just be aware that you can reuse the same program to analyze a different subset of the data set by changing the values of the macro variables.

Note that macro language statements start with a percent sign (%) and macro variable references start with an ampersand (&). Both features are in bold in the following code.

%let repmonth=4;

%let repyear=2014;

%let repmword=%sysfunc(mdy(&repmonth,1,&repyear),monname9.);

proc tabulate data=books.ytdsales;

  where month(datesold)=&repmonth and year(datesold)=&repyear;

  title "Sales During &repmword &repyear";

  class section;

  var saleprice listprice cost;

  tables section all='**TOTAL**',

         (saleprice listprice cost)*(n*f=4. sum*f=dollar10.2);

run;

proc sgpanel data=books.ytdsales;

             where month(datesold)<=&repmonth and

                   year(datesold)=&repyear;

  title "Sales Through &repmword &repyear";

  panelby section;

  hbar datesold / stat=sum fill datalabel response=saleprice;

  format datesold monname3.;

run;

Output 1.3 presents the output from Example 1.3.

Output 1.3 Output from Example 1.3

Changing just the first line of the program from

%let repmonth=4;

to

%let repmonth=5;

runs the same program, but now the program processes the data collected for May. No other editing of the program is required to process this subset. Output 1.4 presents the output for May.

Output 1.4 Output from revised Example 1.3

Where Can the SAS Macro Facility Be Used?

The macro facility can be used with most SAS products. You've seen in the monthly sales report an example of macro programming in Base SAS.

Table 1.1 lists some SAS products and possible macro facility applications that you can create. It also lists existing macro applications that come with SAS.

Table 1.1 SAS macro facility applications

Examples of the SAS Macro Facility

The following examples of the SAS macro facility illustrate some of the tasks that the macro processor can perform for you. There's no need to understand the coding of these programs at this point (although the code is included and might be useful to you later). What you should gain from this section is an idea of the kinds of SAS programming tasks that you can delegate to the macro processor.

In addition to the examples that follow, Example 1.3 demonstrates reuse of the same program by simply changing the values of the macro variables at the beginning of the program. A new subset of data is analyzed each time the values of the macro variables are changed.

It is relatively easy to create and reference these macro variables. Besides being able to reuse your program code, the advantages in using macro variables include reducing coding time and reducing programming errors by not having to edit so many lines of code.

Example 1.4: Displaying System Information

SAS comes with a set of automatic macro variables that you can reference in your SAS programs. Most of these macro variables deal with system-related items like date, time, operating system, and version of SAS. Using these automatically defined macro variables is one of the simplest applications of the macro facility.

Example 1.4 incorporates some of these automatic macro variables, and these macro variables are in bold in the code. Note that the automatic macro variable names are preceded by ampersands. Assume the report was run on February 20, 2014.

title Sales Report;

title2 "As of &systime &sysday &sysdate9";

title3 "Using SAS Version: &sysver";

proc means data=books.ytdsales n sum;

  var saleprice;

run;

Output 1.5 presents the output from Example 1.4.

Output 1.5 Output from Example 1.4

Example 1.5:  Conditional Processing of SAS Steps

Macro programs can use macro variables and macro programming statements to select the steps and the SAS language statements that a SAS program should execute. These conditional processing macro language statements are similar in syntax and structure to SAS language statements.

Macro program DAILY in Example 1.5 contains two PROC steps. The first PROC MEANS step runs daily. The second PROC MEANS step runs only on Fridays. The conditional macro language statements direct the macro processor to run the second PROC step only on Fridays. Assume the program was run on Friday, August 22, 2014.

Macro language statements start with percent signs, and macro variable references start with ampersands.

%macro daily;

  proc means data=books.ytdsales maxdec=2 sum;

    where datesold=today();

    title Daily Sales Report for &sysdate;

    class section;

    var saleprice;

  run;

%if &sysday=Friday %then %do;

     proc means data=books.ytdsales maxdec=2 sum;

       where today()-6 le datesold le today();

       title Weekly Sales Report Week Ending &sysdate9;

       class section;

       var saleprice;

     run;

%end;

%mend daily;

%daily

Output 1.6 presents the output from Example 1.5.

Output 1.6 Output from Example 1.5

Example 1.6: Iterative Processing of SAS Steps

Coding each iteration of a programming process that contains multiple iterations can be a lengthy task. The %DO loops in the macro language can take over some of that iterative coding for you. A macro program can build the code for each iteration of a repetitive programming process based on the specifications of the %DO loop.

Repetitive coding tasks are a breeding ground for bugs in your programs. Thus, turning these tasks over to the macro processor can reduce the number of errors in your SAS programs.

Example 1.6 illustrates iterative processing. It creates 12 data sets, one for each month of the year. Without macro programming, you would have to enter the 12 data set names in the DATA statement and enter all the ELSE statements that direct observations to the right data set. A macro language %DO loop can build those statements for you.

%macro makesets;

  data

 %do i=1 %to 12;

      month&i

%end;

    ;

    set books.ytdsales;

    mosale=month(datesold);

    if mosale=1 then output month1;

%do i=2 %to 12;

      else if mosale=&i then output month&i;

%end;

  run;

%mend makesets;

%makesets

After interpretation by the macro processor, the program becomes:

 data month1 month2 month3 month4 month5 month6

      month7 month8 month9 month10 month11 month12

      ;

   set books.ytdsales;

   mosale=month(datesold);

   if mosale=1 then output month1;

   else if mosale=2 then output month2;

   else if mosale=3 then output month3;

   else if mosale=4 then output month4;

   else if mosale=5 then output month5;

   else if mosale=6 then output month6;

   else if mosale=7 then output month7;

   else if mosale=8 then output month8;

   else if mosale=9 then output month9;

   else if mosale=10 then output month10;

   else if mosale=11 then output month11;

   else if mosale=12 then output month12;

 run;

Macro language statements built the SAS language DATA statement and all of the ELSE statements in the DATA step for you. A few macro programming statements direct the macro processor to build the complete DATA step for you. With this technique, you can avoid the tedious task of entering all the data set names and all the ELSE statements.

Example 1.7: Passing Information between Program Steps

The macro facility can act as a bridge between steps in your SAS programs. The SAS language functions and call routines that interact with the macro facility can transfer information between steps in your SAS programs.

Example 1.7 calculates total sales for two sections in the retailer’s inventory. That value is then inserted in the TITLE statement of the PROC SGPLOT output. The SYMPUTX SAS language routine instructs the macro processor to retain the total sales value in macro variable SOFTPROGSALES after the DATA step finishes. The total sales value is then available to subsequent steps in the program.

data temp;

  set books.ytdsales end=lastobs;

  retain sumsoftprog 0;

  if section in ('Software','Programming') then

    sumsoftprog=sumsoftprog + saleprice;

  if lastobs then

call symputx('softprogsales',put(sumsoftprog,dollar10.2));

run;

proc sgplot data=temp;

  title Sales by Section;

  title2 "Software and Programming Combined: &softprogsales";

  hbar section / stat=sum fill datalabel response=saleprice;

    yaxis display=(nolabel noticks);

  format saleprice dollar10.2;

run;

Output 1.7 presents the output from Example 1.7.

Output 1.7 Output from Example 1.7

Without the SYMPUTX routine, you would have to submit two programs. The first SAS program would calculate the total sales for the two sections. After the first program ends, you find the total sales value in the output. Then, before submitting the second program, you would have to edit the second program and update the TITLE statement with the total sales value that you found in the output from the first program.

Alternatively, you can use PROC SQL to compute the same sum of sales for the software and programming sections and save that sum in a macro variable for use later. The following PROC SQL step uses the INTO clause to create macro variable SUMSOFTPROG.

proc sql noprint;

  select sum(saleprice) format=dollar10.2 into :sumsoftprog

    from books.ytdsales

    where section in ('Software','Programming');

quit;

The PROC SQL step does not create a table so the DATA= option on the PROC SGPLOT step should specify BOOKS.YTDSALES instead of TEMP.

Example 1.8: Interfacing Macro Language and SAS Language Functions

SAS has libraries of functions that you can also use in your macro language code. Some uses of these functions include incorporating information about a data set in a title, checking the existence of a data set, and finding the number of observations in a data set.

Macro program DSREPORT in Example 1.8 produces a PROC MEANS report for a data set whose name is passed as a parameter to DSREPORT. The number of observations and creation date of the data set are obtained with the ATTRN SAS language function, and SAS inserts these attributes in the report title. The PUTN SAS language function formats the date value. Macro program DSREPORT opens and closes the data set with the OPEN and CLOSE SAS language functions. The SAS language functions are underlined in Example 1.8.

%macro dsreport(dsname);

  %*----Open data set dsname;

%let dsid=%sysfunc(open(&dsname));

  %*----How many obs are in the data set?;

%let nlobs=%sysfunc(attrn(&dsid,nlobs));

  %*----When was the data set created?;

%let when = %sysfunc(putn(

%sysfunc(attrn(&dsid,crdte)),datetime9.));

  %*----Close data set dsname identified by dsid;

%let rc=%sysfunc(close(&dsid));

  title Report on Data Set &dsname;

  title2 "Num Obs: &nlobs   Date Created: &when";

  proc means data=&dsname sum maxdec=2;

    class section;

    var saleprice;

  run;

%mend dsreport;

%dsreport(books.ytdsales)

Output 1.8 presents the output from Example 1.8.

Output 1.8 Output from Example 1.8

Example 1.9: Building and Saving a Library of Utility Routines

Your work might frequently require that you program the same process in different applications. Rather than rewriting the code every time, you might be able to write the code once and save it in a macro program. Later when you want to execute that code again, you just reference the macro program. With the macro facility, there are ways to save the code in special libraries and even to save the compiled code in permanent locations. For example, perhaps some of your reports require the same SAS options, titles, and footnotes. You can save these standardizations in a macro program and call the macro program rather than write the statements every time.

You can store macro programs in a special location called an autocall library. Then when you want to submit one of these saved macro programs for compilation and execution during a later SAS session, you only need to tell SAS to look for macro programs in your autocall library, and you do not have to explicitly submit the code in the SAS session. Further, you could make the library available to your workgroup, and thus your workgroup only needs to maintain single copies of macro programs that you all need to use.

The macro program STANDARDOPTS in Example 1.9 submits an OPTIONS statement to ensure that three SAS options are in effect: NODATE, NUMBER, and BYLINE. It also specifies TITLE1 and FOOTNOTE1 statements. Assume STANDARDOPTS is stored in a file named STANDARDOPTS.SAS in Windows directory c:\mymacroprograms. (If you were using UNIX, make sure the filename is in lowercase.)

%macro standardopts;

  options nodate number byline;

  title Book Sales Report;

  footnote1

     Prepared &sysday &sysdate9 at &systime using SAS &sysver;

%mend standardopts;

In a later SAS session, you do not need to explicitly submit the macro program definition. Instead, when you submit the following OPTIONS statement and call macro program STANDARDOPTS, SAS finds the definition of STANDARDOPTS in the c:\mymacroprograms directory, compiles it for you, and executes STANDARDOPTS.

The SASAUTOS option specifies that SAS have access to the autocall library shipped with SAS (sasautos) and to the autocall library in the mymacroprograms folder.

options mautosource sasautos=(sasautos,'c:\mymacroprograms');

%standardopts

After submitting the macro program STANDARDOPTS, the title text on subsequent reports is

Book Sales Report

If STANDARDOPTS was submitted on February 22, 2014, from a SAS session that started at 8:36 using SAS 9.4, the footnote text on subsequent reports would be:

Prepared Friday 22FEB2014 08:36 using SAS 9.4

Chapter 2 Mechanics of Macro Processing

Introduction

The Vocabulary of SAS Processing

SAS Processing without Macro Activity

Understanding Tokens

Tokenizing a SAS Program

Comparing Macro Language Processing and SAS Language Processing

Processing a SAS Program That Contains Macro Language

Introduction

Understanding the steps that SAS takes to process a program will help you determine where macro facility features can be incorporated in your SAS programs. You do not need a detailed knowledge of the mechanics of macro processing to write SAS programs that include macro features. However, an understanding of the timing of macro language processing, as it relates to SAS language processing, can help you write more powerful programs and make it easier for you to debug programs that contain macro features.

The examples in Chapter 1 showed how you can enhance your SAS programming with the macro facility. The examples in this chapter illustrate when and how the macro processor does its work.

There are just a few basic concepts in macro processing to add to your knowledge of SAS processing. If you already know how SAS programs are compiled and executed, you are well on your way to understanding the mechanics of macro processing.

As you read through this chapter, keep in mind that the macro processor is your SAS programming assistant, helping you code your SAS programs.

The Vocabulary of SAS Processing

This chapter uses several terms to describe SAS processing. Table 2.1 reviews these terms.

Table 2.1 Terms commonly used to describe SAS processing

SAS Processing without Macro Activity

SAS programs can be submitted for processing from several locations including:

• an interactive SAS session from the Editor

• a batch program

• a noninteractive program

• SAS Enterprise Guide

• from the command line in the SAS windowing environment

• an SCL SUBMIT block

• the SCL COMPILE command

In all cases, submitted SAS programs start in the input stack. The word scanner takes statements from the input stack and tokenizes the statements into the fundamental units of words and symbols. The word scanner's job is then to direct the tokens to the right location. The word scanner might direct tokens to the DATA step compiler, the macro processor, the command processor, or the