User:Una tantum

From Wikidata
(Redirected from User:Patafisik)
Jump to navigation Jump to search
Babel user information
it-N Questa utente può contribuire con un livello madrelingua in italiano.
fr-3 Cette utilisatrice dispose de connaissances avancées en français.
en-2 This user has intermediate knowledge of English.
la-1 Haec ustrix simplici lingua Latina conferre potest.
de-0 Diese Benutzerin beherrscht Deutsch nicht (oder versteht es nur mit beträchtlichen Schwierigkeiten).
es-0 Esta usuaria no tiene ningún conocimiento del español (o lo entiende con mucha dificultad).
Questo utente partecipa alle attività del Gruppo Wikidata per Musei, Archivi e Biblioteche
Users by language
WLM2018 barnstar

Hello! I'm a Wikimedian.

This user is a member of
WikiProject Italy.

To do

[edit]
  • candidati wikimooc : con coord
  • Pont de la Justice (Q131105733) verde, classé, aggiungi fonti (magari cartacee)
    museo del protestantesimo del Delfinato Q131049447 (giallo, mettere fonti e info)
    Castello di Rolley (Q130859548) giallo, manca foto e cat commons
    Castello di Preïssan (Q130856306) giallo prendi fonti da frwiki, manca foto

castello belgique classé 2 provvedimenti

Problema doppie coordinate per merge

[edit]
coordinate location
Normal rank 44°13'28.751"N, 11°46'14.938"E edit
applies to part, aspect, or form gate
1 reference
stated in Tourer.it
Tourer.it ID 9278
retrieved 2024-04-20
add reference
Preferred rank 44.22462, 11.77064 edit
reason for preferred rank better centered coordinate
Preferred rank 44.22462, 11.77064 edit
reason for deprecated rank error in referenced source or sources
0 references
add reference
add value

Memo

[edit]
place of burial
Normal rank Certosa di Bologna edit
burial plot reference Loggia delle tombe, cippo 257
coordinate location 44.4960371, 11.3080209
Commons category Grave of Mombelli (Certosa, Tombs Loggia)
OpenStreetMap node ID 10763329046
Normal rank Grave of Pawlowski edit
0 references
add reference
add value
Storiaememoriadibologna.it ID
Normal rank ferlini-giuseppe-481611-persona edit
subject named as Ferlini Giuseppe
author name string Mirtide Gavelli
0 references
add reference
add value
Q55103240 e Q55088286?
designazione del patrimonio (P1435) bene tutelato
https://mix-n-match.toolforge.org/#/scraper/new
https://mix-n-match.toolforge.org/#/import/
Label Collector
  1. Collegare Wikidata al mondo: come si usa Mix'n'match (Commons; Youtube)
  2. I gadget: una risorsa per semplificare il lavoro su Wikidata (Commons; Youtube)
  3. Proporre nuovi identificativi su Wikidata (Commons; Youtube)
  4. Le interazioni tra VIAF e Wikidata (Commons; Youtube)
  5. Come è fatto un identificativo esterno su Wikidata (Commons; Youtube)
  6. Come usare il query service su Wikidata (Youtube)
  7. WikiBridge: vedere su Wikidata l'incipit delle voci di Wikipedia (Youtube)
  8. Impostare le preferenze e il common.js su Wikidata (Youtube)

Queries

[edit]
immagini per tombe aggiunte più facilmente su wikidata
  • wikidata query
    fai selezione cobn PetScan es ID 29123664
  • dai il codice a WikiData Free Image Search Tool es
#defaultView:Map
#opere di Pasquale Rizzoli in Certosa, con item su wikidata e con immagine e coordinate opzionali se si vuole visualizzare la mappa con ImageGrid o con Map
SELECT ?item ?itemLabel ?image ?itemcoord
WHERE {
 ?item wdt:P170 wd:Q3897132.
  ?item wdt:P276 wd:Q3671680 .
 OPTIONAL { ?item wdt:P625 ?itemcoord } .
 OPTIONAL { ?item wdt:P18 ?image } .
 SERVICE wikibase:label { bd:serviceParam wikibase:language "en,it". }
}
Try it! 
#opere di Pasquale Rizzoli in Certosa, con item su wikidata e con immagine opzionale se si vuole visualizzarla 
SELECT ?item ?itemLabel ?image
WHERE {
 ?item wdt:P170 wd:Q3897132.
  ?item wdt:P276 wd:Q3671680 .
 OPTIONAL { ?item wdt:P18 ?image } .
 SERVICE wikibase:label { bd:serviceParam wikibase:language "en,it". }
}
Try it!

(scegli "image grid" per visualizzare immagini) 

#tombe della Certosa con elementi su wikidata senza foto, nonostante esista la categoria collegata su Commons (elementi che hanno una categoria connessa in Commons ma nessuna P18)
SELECT DISTINCT ?item ?itemlabel ?itemDescription ?imagelink WHERE {
  ?item wdt:P17 wd:Q38 .
  ?item wdt:P276 wd:Q3671680 .
  ?item wdt:P373 ?commons .
  MINUS { ?item wdt:P18 ?image } .
  BIND(IRI(CONCAT('https://commons.wikimedia.org/wiki/', ?image)) AS ?imagelink ) .
}
LIMIT 100
Try it!

(da Alexmar983) 

#defaultView:Map
#title:Mappa dei memoriali di guerra in Italia (by Alexmar983)
SELECT ?monumento ?monumentoLabel ?comuneLabel ?coord
WHERE {
  ?monumento wdt:P31 wd:Q575759 .
  ?monumento wdt:P17 wd:Q38 .
  OPTIONAL { ?monumento wdt:P625 ?coord } .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?monumentoLabel
Mappa dei memoriali di guerra in Italia (by Alexmar983) 
#defaultView:Map{"hide": "?coords"} 
#mappa dei musei
SELECT DISTINCT ?museum ?museumLabel (SAMPLE(?coords) AS ?coords) #(SAMPLE(?image) AS ?image)
?url ?layer WHERE {
?museum wdt:P31 ?type .?type wdt:P279? wd:Q33506. ?museum wdt:P625 ?coords
#OPTIONAL {?museum wdt:P18 ?image}
OPTIONAL {?museum wdt:P856 ?url}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
?museum rdfs:label ?museumLabel. ?type rdfs:label ?layer }
} GROUP BY ?museum ?museumLabel ?url ?layer
ORDER BY UCASE(?layer)
Try it!

in corso (vorrei più valori per 3 tipi di entità dei Cartigli? ES; * Query Service le biblioteche in E-R con coordinate su Wikidata, di cui quelle aderenti al NILDE in altro colore (mappa) ) 

#mappa dei Cartigli di Bologna
#defaultView:Map
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?comuneLabel ?itemcoord ?layer1 ?layer2 ?layer3 WHERE {
  {?item wdt:P31/wdt:P279* wd:Q811979} UNION {?item wdt:P31 wd:Q1437299 .} UNION {?item wdt:P31 wd:Q12284 .} UNION {?item wdt:P31 wd:Q22746 .} UNION {?item wdt:P31 wd:Q1107656 .}
   ?item p:P9327 ?statement0.
   ?statement0 (ps:P9327) _:anyValueP9327.
   ?item wdt:P131 ?comune .
   ?comune wdt:P625 ?comunecoord .
   ?item wdt:P625 ?itemcoord .
     OPTIONAL { ?item wdt:P31/wdt:P279* wd:Q1437299 . BIND("CANALI" as ?layer2) } .
     OPTIONAL { ?item wdt:P31/wdt:P279* wd:Q12284 . BIND("CANALI" as ?layer2) } .
     OPTIONAL { ?item wdt:P31/wdt:P279* wd:Q22746 . BIND("GIARDINI PUBBLICI" as ?layer3) } .
     OPTIONAL { ?item wdt:P31/wdt:P279* wd:Q1107656 . BIND("GIARDINI PUBBLICI" as ?layer3) } .
     OPTIONAL { ?item wdt:P31/wdt:P279* wd:Q41176 . BIND("EDIFICI STORICI" as ?layer1) } .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en, it, fr, es, de". }
}
Try it!

Altro

[edit]
  • NB gli oggetti della collezione sono su una carta ma non hanno coordinate: le coordinate sono date dalla città di scoperta, le coordinate sono quelle della città.
#title: Lieux de découverte des objets des collections du musée de Bretagne
#defaultView:Map
SELECT ?q ?qLabel ?locLabel ?coord WHERE {
  ?q wdt:P195 wd:Q3329701 ;
     wdt:P189 ?loc .
  ?loc wdt:P625 ?coord .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". ?q rdfs:label ?qLabel . ?depeint rdfs:label ?depeintLabel }
}
Lieux de découverte des objets des collections du musée de Bretagne 
#aree naturali protette della Valle d'Aosta su Wikidata, con EUAP senza la proprietà OpenStreetMap relation ID (P402) con voce su itwiki
SELECT DISTINCT ?item ?itemLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". }
  {
  SELECT DISTINCT ?item WHERE {
    ?item p:P31 ?statement0.
    ?statement0 (ps:P31/(wdt:P279*)) wd:Q473972.
  ?item p:P131 ?statement4.
      ?statement4 (ps:P131/(wdt:P131*)) wd:Q1222.
    ?item p:P4800 ?statement3.
    ?statement3 (ps:P4800) _:anyValueP4800.
  }
    }
  MINUS {
    ?item p:P402 ?statement2.
    ?statement2 (ps:P402) _:anyValueP402.
    }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". }
  FILTER EXISTS { ?sitelink_it schema:about ?item;
                schema:isPartOf <https://it.wikipedia.org/> .
                 }
  }
LIMIT 100
Try it! 
#idem per parchi regionali Lazio
SELECT DISTINCT ?item ?itemLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". }
  {
  SELECT DISTINCT ?item WHERE {
    ?item p:P31 ?statement0.
    ?statement0 (ps:P31/(wdt:P279*)) wd:Q6063204.
  ?item p:P131 ?statement4.
      ?statement4 (ps:P131/(wdt:P131*)) wd:Q1282.
    ?item p:P4800 ?statement3.
    ?statement3 (ps:P4800) _:anyValueP4800.
  }
    }
  MINUS {
    ?item p:P402 ?statement2.
    ?statement2 (ps:P402) _:anyValueP402.
    }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". }
  FILTER EXISTS { ?sitelink_it schema:about ?item;
                schema:isPartOf <https://it.wikipedia.org/> .
                 }
  }
LIMIT 100
Try it! 
#aree naturali protette italiane  su Wikidata con EUAP senza la proprietà OpenStreetMap relation ID (P402) con voce su itwiki
SELECT DISTINCT ?item ?itemLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". }
  {
  SELECT DISTINCT ?item WHERE {
    ?item p:P31 ?statement0.
    ?statement0 (ps:P31/(wdt:P279*)) wd:Q473972.
    ?item p:P17 ?statement1.
    ?statement1 (ps:P17/(wdt:P279*)) wd:Q38.
    ?item p:P4800 ?statement3.
    ?statement3 (ps:P4800) _:anyValueP4800.
  }
    }
  MINUS {
    ?item p:P402 ?statement2.
    ?statement2 (ps:P402) _:anyValueP402.
    }
  ?item p:P131 ?statement4.
      ?statement4 (ps:P131/(wdt:P131*)) wd:Q1222.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". }
  FILTER EXISTS { ?sitelink_it schema:about ?item;
                schema:isPartOf <https://it.wikipedia.org/> .
                 }
  }
LIMIT 100
Try it! 
#aree naturali protette italiane su Wikidata con EUAP senza la proprietà OpenStreetMap relation ID (P402) e senza voce su itwiki
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?sitelink_it ?sitelink_en ?sitelink_fr WHERE {
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en, it, fr, es, de". }
  {
    SELECT DISTINCT ?item WHERE {
      ?item p:P31 ?statement0.
      ?statement0 (ps:P31/(wdt:P279*)) wd:Q473972.
      ?item p:P4800 ?statement1.
      ?statement1 (ps:P4800) _:anyValueP4800.
      MINUS {
        ?item p:P402 ?statement2.
        ?statement2 (ps:P402) _:anyValueP402.
        ?sitelink_it schema:about ?item;
                schema:isPartOf <https://it.wikipedia.org/> .
    }
  optional {
      ?sitelink_fr schema:about ?item;
                schema:isPartOf <https://fr.wikipedia.org/> .
    }
  optional {
      ?sitelink_en schema:about ?item;
                schema:isPartOf <https://en.wikipedia.org/> .
    }
  }
  ORDER BY DESC (?sitelinks)
  }
}
LIMIT 100
Try it! 
#mappa dei Cartigli di Bologna senza voce su itwiki
#defaultView:Map
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?comuneLabel ?itemcoord  ?sitelink_it ?sitelink_en ?sitelink_fr WHERE {
  {?item wdt:P31/wdt:P279* wd:Q811979} UNION {?item wdt:P31 wd:Q1437299 .}
   ?item p:P9327 ?statement0.
   ?statement0 (ps:P9327) _:anyValueP9327.
   ?item wdt:P131 ?comune .
   ?comune wdt:P625 ?comunecoord .
   ?item wdt:P625 ?itemcoord .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en, it, fr, es, de". }
  MINUS {
      ?sitelink_it schema:about ?item;
                schema:isPartOf <https://it.wikipedia.org/> .
    }
  optional {
      ?sitelink_fr schema:about ?item;
                schema:isPartOf <https://fr.wikipedia.org/> .
    }
  optional {
      ?sitelink_en schema:about ?item;
                schema:isPartOf <https://en.wikipedia.org/> .
    }
  }
  ORDER BY DESC (?sitelinks)
LIMIT 100
Try it! 
#mappa dei Cartigli di Bologna
#defaultView:Map
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?comuneLabel ?itemcoord WHERE {
  {?item wdt:P31/wdt:P279* wd:Q811979} UNION {?item wdt:P31 wd:Q1437299 .}
   ?item p:P9327 ?statement0.
   ?statement0 (ps:P9327) _:anyValueP9327.
   ?item wdt:P131 ?comune .
   ?comune wdt:P625 ?comunecoord .
   ?item wdt:P625 ?itemcoord .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en, it, fr, es, de". }
}
Try it! 
#artisti nati o morti a Bologna, le cui opere siano nel Pubblico Dominio al 1° gennaio 2024
SELECT DISTINCT ?item ?itemLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
  {
    SELECT DISTINCT ?item WHERE {
      ?item p:P31 ?statement0.
      ?statement0 (ps:P31/(wdt:P279*)) wd:Q5.
      ?item p:P570 ?statement_1.
      ?statement_1 psv:P570 ?statementValue_1.
      ?statementValue_1 wikibase:timePrecision ?precision_1.
      FILTER(?precision_1 >= 11 )
      ?statementValue_1 wikibase:timeValue ?P570_1.
      FILTER(?P570_1 < "+1953-12-31T00:00:00Z"^^xsd:dateTime)
      {
        ?item p:P19 ?statement2.
        ?statement2 (ps:P19/(wdt:P279*)) wd:Q1891.
      }
      UNION
      {
        ?item p:P20 ?statement3.
        ?statement3 (ps:P20/(wdt:P279*)) wd:Q1891.
      }
      {
        ?item p:P106 ?statement4.
        ?statement4 (ps:P106/(wdt:P279*)) wd:Q483501.
      }
      UNION
      {
        ?item p:P106 ?statement5.
        ?statement5 (ps:P106/(wdt:P279*)) wd:Q1281618.
      }
      UNION
      {
        ?item p:P106 ?statement6.
        ?statement6 (ps:P106/(wdt:P279*)) wd:Q1028181.
      }
    }
    LIMIT 100
  }
}
Try it! 
#Elenco di donne presenti nel catalogo BEIC e su Wikipedia in francese ma non in italiano per tradurre la voce. La lista è ordinata per numero di lingue in cui la voce è presente.
SELECT ?item (COUNT(?sitelink) AS ?linkcount) WHERE {
  ?item wdt:P1343 wd:Q51955019 .
  ?item wdt:P21 wd:Q6581072 .
  ?sitelink schema:about ?item .
  FILTER NOT EXISTS { ?wiki schema:about ?item; schema:isPartOf <https://it.wikipedia.org/> . }
  FILTER EXISTS { ?sitelink_fr schema:about ?item;
                schema:isPartOf <https://fr.wikipedia.org/> .
                }
  }
GROUP BY(?item)
ORDER BY DESC(?linkcount)
LIMIT 200
Try it! 
#item con identificativo dei Cartigli di Bologna nelle edizioni linguistiche
SELECT DISTINCT ?item ?itemLabel ?sitelink_it ?sitelink_en ?sitelink_fr ?sitelink_de ?sitelink_es ?sitelink_ja WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,it,fr,es,de,ja". }
  {
    SELECT DISTINCT ?item WHERE {
      ?item p:P9327 ?statement0.
      ?statement0 (ps:P9327) _:anyValueP9327.
    }
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,it,fr,es,de,ja". }
  optional {
      ?sitelink_it schema:about ?item;
                schema:isPartOf <https://it.wikipedia.org/> .
    }
  optional {
      ?sitelink_fr schema:about ?item;
                schema:isPartOf <https://fr.wikipedia.org/> .
    }
  optional {
      ?sitelink_en schema:about ?item;
                schema:isPartOf <https://en.wikipedia.org/> .
    }
  optional {
      ?sitelink_de schema:about ?item;
                schema:isPartOf <https://de.wikipedia.org/> .
    }
  optional {
      ?sitelink_ja schema:about ?item;
                schema:isPartOf <https://ja.wikipedia.org/> .
    }
  optional {
      ?sitelink_es schema:about ?item;
                schema:isPartOf <https://es.wikipedia.org/> .
    }
  }
  ORDER BY DESC (?sitelinks)
Try it! 
#Artisti presenti in Certosa i cui diritti d'autore non sono scaduti e che abbiano categoria su Commons
SELECT DISTINCT ?item ?itemLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
  {
    SELECT DISTINCT ?item WHERE {
      ?item p:P31 ?statement0.
      ?statement0 (ps:P31/(wdt:P279*)) wd:Q5.
      ?item p:P6379 ?statement1.
      ?statement1 (ps:P6379/(wdt:P279*)) wd:Q3671680.
      ?item p:P7763 ?statement2.
      ?statement2 (ps:P7763/(wdt:P279*)) wd:Q73555012.
      ?item p:P373 ?statement3.
      ?statement3 (ps:P373) _:anyValueP373.
    }
    LIMIT 300
  }
}
Try it! 
#Artisti presenti in Certosa
SELECT DISTINCT ?item ?itemLabel  WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,it,fr,es,de,ja". }
  {
    SELECT DISTINCT ?item WHERE {
      ?item p:P31 ?statement0.
      ?statement0 (ps:P31/(wdt:P279*)) wd:Q5.
      ?item p:P6379 ?statement1.
      ?statement1 (ps:P6379/(wdt:P279*)) wd:Q3671680.
      ?item p:
    }
  }
  }
Try it! 
#title:Paintings once owned by Red Flag Names

#defaultView:ImageGrid
SELECT DISTINCT ?pic ?painting ?paintingLabel ?location ?locationLabel
WHERE
{
  ?painting wdt:P31 wd:Q3305213; #painting
            wdt:P127 [ wdt:P1840 wd:Q30335959 ].  #the painting is owned by someone who is a red flag name
  OPTIONAL  {?painting wdt:P276 ?location.}
  ?painting wdt:P18 ?pic.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
}
Paintings once owned by Red Flag Names 
#Donne sepolte alla Certosa di Bologna con elemento Wikidata ma senza voce su it.wiki
SELECT ?persona ?personaLabel ?personaDescription ?sitelink_it ?sitelink_en ?sitelink_fr
WHERE {
       ?persona wdt:P31 wd:Q5 .
       ?persona wdt:P21 wd:Q6581072 .
       ?persona wdt:P119 wd:Q3671680 .
   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,it,fr". }
  MINUS {
      ?sitelink_it schema:about ?persona;
                schema:isPartOf <https://it.wikipedia.org/> .
    }
  optional {
      ?sitelink_fr schema:about ?persona;
                schema:isPartOf <https://fr.wikipedia.org/> .
    }
  optional {
      ?sitelink_en schema:about ?persona;
                schema:isPartOf <https://en.wikipedia.org/> .
    }
  }
  ORDER BY DESC (?sitelinks)
LIMIT 100
Try it! 
#Artisti presenti in Certosa nelle edizioni linguistiche
SELECT DISTINCT ?item ?itemLabel ?sitelink_it ?sitelink_en ?sitelink_fr ?sitelink_de ?sitelink_es ?sitelink_ja WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,it,fr,es,de,ja". }
  {
    SELECT DISTINCT ?item WHERE {
      ?item p:P31 ?statement0.
      ?statement0 (ps:P31/(wdt:P279*)) wd:Q5.
      ?item p:P6379 ?statement1.
      ?statement1 (ps:P6379/(wdt:P279*)) wd:Q3671680.
    }
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,it,fr,es,de,ja". }
  optional {
      ?sitelink_it schema:about ?item;
                schema:isPartOf <https://it.wikipedia.org/> .
    }
  optional {
      ?sitelink_fr schema:about ?item;
                schema:isPartOf <https://fr.wikipedia.org/> .
    }
  optional {
      ?sitelink_en schema:about ?item;
                schema:isPartOf <https://en.wikipedia.org/> .
    }
  optional {
      ?sitelink_de schema:about ?item;
                schema:isPartOf <https://de.wikipedia.org/> .
    }
  optional {
      ?sitelink_ja schema:about ?item;
                schema:isPartOf <https://ja.wikipedia.org/> .
    }
  optional {
      ?sitelink_es schema:about ?item;
                schema:isPartOf <https://es.wikipedia.org/> .
    }
  }
Try it! 
#Conservatori in Italia con elementi Wikidata e voce su Wikipedia 
SELECT ?item ?itemLabel ?itemDescription ?sitelink_it ?sitelink_en ?sitelink_fr ?sitelink_de ?sitelink_es ?sitelink_ja WHERE 
    {?item wdt:P31 wd:Q184644.
     ?item wdt:P17 wd:Q38.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,it,fr,es,de,ja". }
  optional {
      ?sitelink_it schema:about ?item;
                schema:isPartOf <https://it.wikipedia.org/> .
    }
  optional {
      ?sitelink_fr schema:about ?item;
                schema:isPartOf <https://fr.wikipedia.org/> .
    }
  optional {
      ?sitelink_en schema:about ?item;
                schema:isPartOf <https://en.wikipedia.org/> .
    }
  optional {
      ?sitelink_de schema:about ?item;
                schema:isPartOf <https://de.wikipedia.org/> .
    }
  optional {
      ?sitelink_ja schema:about ?item;
                schema:isPartOf <https://ja.wikipedia.org/> .
    }
  optional {
      ?sitelink_es schema:about ?item;
                schema:isPartOf <https://es.wikipedia.org/> .
    }

}
Try it! 
#castelli in Emilia-Romagna presenti su Wikidata e con coordinate
#defaultView:Map
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?comuneLabel ?coord WHERE {
  {?item wdt:P31/wdt:P279* wd:Q23413 } UNION {?item wdt:P31 wd:Q856584 .} UNION {?item wdt:P31 wd:Q17715832 .}
   ?item (wdt:P131)* wd:Q1263 .
   ?item wdt:P131 ?comune .
   ?comune wdt:P625 ?comunecoord .
  OPTIONAL { ?item wdt:P625 ?itemcoord . }
  BIND(IF(BOUND(?itemcoord),?itemcoord,?comunecoord) AS ?coord)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en, it, fr, es, de". }
}
Try it!

3 tipi di richiesta, v1 e v2 da 84 risultati, v3 da 40 risultati.

valuta se ?item wdt:P131/wdt:P131/wdt:P131* wd:Q1263. corrisponde a ?item (wdt:P131)* wd:Q1263 .

v1 

#biblioteche in Emilia-Romagna presenti su Wikidata, di cui alcuni con coordinate geografiche
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?comuneLabel ?coord WHERE {
  {?item wdt:P31/wdt:P279* wd:Q7075} UNION {?item wdt:P31 wd:Q856584 .}
   ?item wdt:P131/wdt:P131/wdt:P131* wd:Q1263 .
   ?item wdt:P131 ?comune .
   ?comune wdt:P625 ?comunecoord .
  OPTIONAL { ?item wdt:P625 ?itemcoord . }
  BIND(IF(BOUND(?itemcoord),?itemcoord,?comunecoord) AS ?coord)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en, it, fr, es, de". }
}
Try it!

v2 

#biblioteche in Emilia-Romagna presenti su Wikidata e aderenti al NILDE
#defaultView:Map
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?comuneLabel ?coord WHERE {
  {?item wdt:P31/wdt:P279* wd:Q7075} UNION {?item wdt:P31 wd:Q856584 .}
   ?item (wdt:P131)* wd:Q1263 .
   ?item wdt:P463 wd:Q21272726 .
   ?item wdt:P131 ?comune .
   ?comune wdt:P625 ?comunecoord .
  OPTIONAL { ?item wdt:P625 ?itemcoord . }
  BIND(IF(BOUND(?itemcoord),?itemcoord,?comunecoord) AS ?coord)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en, it, fr, es, de". }
}
Try it!

v3 (solo biblioteche e non sottoinsiemi es biblioteche specializzate) 

#Biblioteche dell'Emilia-Romagna aventi le coordinate geografiche su Wikidata
#defaultView:Map
SELECT DISTINCT ?i ?iLabel ?iDescription ?coord ?inst ?instLabel
WHERE {
  VALUES ?instance { wd:Q7075 }
  ?i wdt:P31 ?instance .
  ?i (wdt:P131)* wd:Q1263 . 
  ?i wdt:P131 ?inst .
  ?inst wdt:P625 ?instcoord .
  OPTIONAL { ?i wdt:P625 ?icoord . }
  BIND(IF(BOUND(?icoord),?icoord,?instcoord) AS ?coord)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,enit,fr,es,de". }
}
Try it! 
#biblioteche in Emilia-Romagna di NILDE presenti su Wikidata
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?comuneLabel WHERE {
  {?item wdt:P31/wdt:P279* wd:Q7075} UNION {?item wdt:P31 wd:Q856584 .}
   ?item wdt:P131/wdt:P131/wdt:P131* wd:Q1263 .
   ?item wdt:P463 wd:Q21272726 .
   ?item wdt:P131 ?comune .
   ?comune wdt:P625 ?comunecoord .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en, it, fr, es, de". }
}
Try it!
Cette image est interactive en cliquant dessus
Carte interactive de tous les Wikimédiens en résidence listés dans Wikidata, triés par année. (requête) 
#elementi Wikidata con TourER ID e voce su Wikipedia 
SELECT ?item ?itemLabel ?itemDescription ?tourerid ?sitelink_it ?sitelink_en ?sitelink_fr WHERE {
  ?item wdt:P4133 ?tourerid.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  optional {
      ?sitelink_it schema:about ?item;
                schema:isPartOf <https://it.wikipedia.org/> .
    }
  optional {
      ?sitelink_en schema:about ?item;
                schema:isPartOf <https://en.wikipedia.org/> .
    }
  optional {
      ?sitelink_fr schema:about ?item;
                schema:isPartOf <https://fr.wikipedia.org/> .
    }
}
order by xsd:integer(?tourerid)
Try it! 
#Scrittrici italiane senza firma su Wikidata
SELECT ?author ?authorLabel ?sitelinks WHERE {
  ?author wdt:P21 wd:Q6581072;
    wdt:P106 wd:Q36180;
    wdt:P570 ?died;
    wikibase:sitelinks ?sitelinks.
  MINUS { ?author wdt:P109 ?signature. }
  OPTIONAL { ?wikisourcePage schema:about ?author. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "it". }
  ?author wdt:P27 wd:Q38.
}
GROUP BY ?author ?authorLabel ?sitelinks
ORDER BY DESC (?sitelinks)
LIMIT 100
Try it! 
#donne non presenti su it.wiki ma su altre wiki? da en:Wikipedia:WikiProject_Women_in_Red/Number_of_links
SELECT ?item ?linkcount
WHERE {
  hint:Query hint:optimizer "None".
  hint:Query hint:maxParallel 50 .
  hint:Query hint:chunkSize 1000 .
  hint:Query hint:queryEngineChunkHandler "Native" . # Native/Managed
  hint:Query hint:filterExists "VectoredSubPlan" . # SubQueryLimitOne/VectoredSubPlan
  ?item wdt:P21 wd:Q6581072 .  # gender is female
  ?item wikibase:sitelinks ?linkcount .
  FILTER ( ?linkcount >= 7 )
  FILTER( ?item NOT IN (wd:Q4617, wd:Q180807, wd:Q234649, wd:Q237119, wd:Q264096, wd:Q270980, wd:Q326474, wd:Q464944, wd:Q468313, wd:Q8265475, wd:Q17413110, wd:Q19940498, wd:Q15397819, wd:Q13406268, wd:Q4115189)) # don’t count those who are redirects or any sandboxes
  FILTER NOT EXISTS { ?wen schema:about ?item . ?wen schema:isPartOf <https://it.wikipedia.org/>. }
  FILTER NOT EXISTS { ?item wdt:P106 wd:Q488111 } # don’t include porn actors
  ?item wdt:P31 wd:Q5 . # human
}
ORDER BY DESC(?linkcount)
LIMIT 100
Try it! 
#Luoghi della cultura che hanno la voce su it.wiki
SELECT ?luogoCultura ?luogoCulturaLabel ?luogoCulturaDescription ?UnitAmmLabel ?DBUnicoMiBACT ?page_titleIT
WHERE {
       ?luogoCultura wdt:P17 wd:Q38 .
       ?luogoCultura wdt:P5782 ?DBUnicoMiBACT .
       ?luogoCultura wdt:P131 ?UnitAmm .
       ?article schema:about ?luogoCultura ; schema:isPartOf <https://it.wikipedia.org/> ;  schema:name ?page_titleIT .
       ?luogoCultura rdfs:label ?LabelIT filter (lang(?LabelIT) = "it") .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "it,en". }
  
             }
LIMIT 100
Try it! 
#Luoghi della cultura senza voce su it.wiki (occhio ai falsi positivi)
SELECT ?luogoCultura ?luogoCulturaLabel ?luogoCulturaDescription ?UnitAmmLabel ?DBUnicoMiBACT ?page_titleIT
WHERE {
       ?luogoCultura wdt:P17 wd:Q38 .
       ?luogoCultura wdt:P5782 ?DBUnicoMiBACT .
       ?luogoCultura wdt:P131 ?UnitAmm .
       MINUS { ?article schema:about ?luogoCultura ; schema:isPartOf <https://it.wikipedia.org/> ;  schema:name ?page_titleIT .
       ?luogoCultura rdfs:label ?LabelIT filter (lang(?LabelIT) = "it") .
              }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "it,en". }
  
             }
LIMIT 100
Try it! 
#Persone con opere nella collezione Certosa di Bologna
SELECT ?persona ?CertosaBo ?personaLabel ?personaDescription ?haopere
WHERE {
  {?persona wdt:P31 wd:Q5 .}
       ?persona wdt:P6379 wd:Q3671680 .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "it,en". }
             }
LIMIT 500
Try it! 
#Luoghi della cultura del comune di Bologna senza voce su it.wiki (occhio ai falsi positivi)
SELECT ?luogoCultura ?luogoCulturaLabel ?luogoCulturaDescription ?UnitAmmLabel ?DBUnicoMiBACT ?page_titleIT
WHERE {
       ?luogoCultura wdt:P131 wd:Q1891 .
       ?luogoCultura wdt:P5782 ?DBUnicoMiBACT .
       ?luogoCultura wdt:P131 ?UnitAmm .
       MINUS { ?article schema:about ?luogoCultura ; schema:isPartOf <https://it.wikipedia.org/> ;  schema:name ?page_titleIT .
       ?luogoCultura rdfs:label ?LabelIT filter (lang(?LabelIT) = "it") .
              }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "it,en". }
  
             }
LIMIT 100
Try it! 
#Cartigli di Bologna
SELECT ?edificio ?edificioLabel ?edificioDescription ?cartigli
WHERE {
  {?edificio wdt:P31 wd:Q41176 .} UNION {?edificio wdt:P31 wd:Q16560 .} UNION {?edificio wdt:P31 wd:Q16970 .} UNION {?edificio wdt:P31 wd:Q2651004 .} UNION {?edificio wdt:P31 wd:Q12518 .} UNION {?edificio wdt:P31 wd:Q24398318 .} UNION {?edificio wdt:P31 wd:Q35112127 .} 
       ?edificio wdt:P131 wd:Q1891 .
       ?edificio wdt:P9327 ?cartigli .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "it,en". }
             }
Try it! 
#Doppioni Tourer.it > Unique value constraint report for P4133: report listing each item
SELECT DISTINCT ?item1 ?item1Label ?item2 ?item2Label ?value 
{
	?item1 wdt:P4133 ?value .
	?item2 wdt:P4133 ?value .
	FILTER( ?item1 != ?item2 && STR( ?item1 ) < STR( ?item2 ) ) .
	SERVICE wikibase:label { bd:serviceParam wikibase:language "en" } .
}
LIMIT 100
Try it! 
# Doppioni Tourer.it a Bologna > Unique value constraint report for P4133: report listing each item
SELECT DISTINCT ?item1 ?item1Label ?item2 ?item2Label ?value
{
	?item1 wdt:P4133 ?value .
	?item2 wdt:P4133 ?value .
    ?item1 (wdt:P131)* wd:Q1891
	FILTER( ?item1 != ?item2 && STR( ?item1 ) < STR( ?item2 ) ) .
	SERVICE wikibase:label { bd:serviceParam wikibase:language "en,it,fr" } .
}
LIMIT 100
Try it! 
#Palazzi, chiese ed edifici di Bologna presenti nel catalogo Tourer
SELECT ?edificio ?edificioLabel ?edificioDescription ?tourer
WHERE {
  {?edificio wdt:P31 wd:Q41176 .} UNION {?edificio wdt:P31 wd:Q16560 .} UNION {?edificio wdt:P31 wd:Q16970 .} UNION {?edificio wdt:P31 wd:Q2651004 .} UNION {?edificio wdt:P31 wd:Q12518 .} UNION {?edificio wdt:P31 wd:Q24398318 .}
       ?edificio wdt:P131 wd:Q1891 .
       ?edificio wdt:P4133 ?tourer .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "it,en". }
             }
LIMIT 100
Try it! 
#foto su commons per elementi WLM su wikidata (elementi di WLM che hanno una categoria connessa in Commons ma nessuna P18, e per cui almeno un'immagine in Commons riporta lo stesso ID WLM)
SELECT DISTINCT ?item ?imagelink WHERE {
  ?item wdt:P17 wd:Q38 .
  ?item wdt:P2186 ?wlmid .
  ?item wdt:P373 ?commons .
  MINUS { ?item wdt:P18 ?image } .
  BIND(CONCAT('"Wiki Loves Monuments Italia" insource:', ?wlmid) AS ?needle ) .
  SERVICE wikibase:mwapi {
      bd:serviceParam wikibase:endpoint "commons.wikimedia.org" .
      bd:serviceParam wikibase:api "Search" .
      bd:serviceParam mwapi:srnamespace "6" .
      bd:serviceParam mwapi:srsearch ?needle .
      bd:serviceParam mwapi:srlimit "1" .
      ?image wikibase:apiOutput mwapi:title .
    }
  BIND(IRI(CONCAT('https://commons.wikimedia.org/wiki/', ?image)) AS ?imagelink ) .
}
LIMIT 100
Try it!
  • Musei dell'Emilia-Romagna
cfr con 92 + 9 [5]
#Musei dell'Emilia-Romagna
#defaultView:Map
SELECT DISTINCT ?i ?iLabel ?iDescription ?coord ?inst ?instLabel
WHERE {
  VALUES ?instance { wd:Q33506 }
  ?i wdt:P31 ?instance .
  ?i (wdt:P131)* wd:Q1263 . 
  ?i wdt:P131 ?inst .
  ?inst wdt:P625 ?instcoord .
  OPTIONAL { ?i wdt:P625 ?icoord . }
  BIND(IF(BOUND(?icoord),?icoord,?instcoord) AS ?coord)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
}
Try it!


  • Musei nella città metropolitana di Bologna
cfr con 92 + 9 [6]
#Musei della città metropolitana di Bologna
#defaultView:Map
SELECT DISTINCT ?i ?iLabel ?iDescription ?coord ?inst ?instLabel
WHERE {
  VALUES ?instance { wd:Q33506 }
  ?i wdt:P31 ?instance .
  ?i (wdt:P131)* wd:Q18288145 . 
  ?i wdt:P131 ?inst .
  ?inst wdt:P625 ?instcoord .
  OPTIONAL { ?i wdt:P625 ?icoord . }
  BIND(IF(BOUND(?icoord),?icoord,?instcoord) AS ?coord)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
}
Try it!
  • Musei di Bologna
cfr con 41 [7]
cfr con QAnswer museums in Bologna
#Musei di Bologna
#defaultView:Map
SELECT DISTINCT ?i ?iLabel ?iDescription ?coord ?inst ?instLabel
WHERE {
  VALUES ?instance { wd:Q33506 }
  ?i wdt:P31 ?instance .
  ?i (wdt:P131)* wd:Q1891 . 
  ?i wdt:P131 ?inst .
  ?inst wdt:P625 ?instcoord .
  OPTIONAL { ?i wdt:P625 ?icoord . }
  BIND(IF(BOUND(?icoord),?icoord,?instcoord) AS ?coord)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
}
Try it!
  • Palazzi di Bologna
cfr. 100 QAnswer Palaces in Bologna
261 risultati in Tourer.it
#Palazzi di Bologna
#defaultView:Map
SELECT DISTINCT ?i ?iLabel ?iDescription ?coord ?inst ?instLabel
WHERE {
  VALUES ?instance { wd:Q16560 }
  ?i wdt:P31 ?instance .
  ?i (wdt:P131)* wd:Q1891 . 
  ?i wdt:P131 ?inst .
  ?inst wdt:P625 ?instcoord .
  OPTIONAL { ?i wdt:P625 ?icoord . }
  BIND(IF(BOUND(?icoord),?icoord,?instcoord) AS ?coord)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
}
Try it!
  • Certosa di Bologna
#Personaggi enciclopedici sepolti alla Certosa di Bologna
SELECT ?persona ?CertosaBo ?personaLabel ?personaDescription ?luogosepoltura
WHERE {
  {?persona wdt:P31 wd:Q5 .}
       ?persona wdt:P119 wd:Q3671680 .
       ?luogosepoltura wdt:P119 ?CertosaBo .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "it,en". }
             }
LIMIT 100
Try it! 
#Artisti con opere alla Certosa di Bologna
SELECT ?persona ?CertosaBo ?personaLabel ?personaDescription
WHERE {
  {?persona wdt:P31 wd:Q5 .}
       ?persona wdt:P6379 wd:Q3671680 .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "it,en,fr". }
             }
LIMIT 500
Try it! 
#Artisti con opere alla Certosa di Bologna senza voce su it.wiki, e n. voci in altre lingue o progetti Wikimedia
SELECT ?item ?itemLabel ?cnt WHERE {
{
  SELECT ?item (COUNT(?sitelink) AS ?cnt) WHERE { 
  ?item wdt:P31 wd:Q5 .
  ?item wdt:P6379 wd:Q3671680 .
  ?sitelink schema:about ?item .
  FILTER NOT EXISTS {
    ?article schema:about ?item .
    ?article schema:isPartOf <https://it.wikipedia.org/> . #Targeting Wikipedia language where subjects has no article.
  }
  } GROUP BY ?item ORDER BY DESC (?cnt) LIMIT 1000 #Sorted by amount of articles in other languages. Result limited to 1000 lines to not have a timeout error.
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,fr,it,es,de" }  #Service to resolve labels in (fallback) languages: automatic user language, English, French, Spanish, German.
} ORDER BY DESC (?cnt)
Try it! 


#Opere nalla collezione Certosa di Bologna
SELECT ?item ?itemLabel ?itemDescription  

WHERE {
  ?item wdt:P195 wd:Q3671680.
  {?item wdt:P31 wd:Q4989906 .} UNION {?item wdt:P31 wd:Q381885 .} UNION {?item wdt:P31 wd:Q173387 .} UNION {?item wdt:P31 wd:Q179700 .} UNION {?item wdt:P31 wd:Q6023295 .} UNION {?edificio wdt:P31 wd:Q219423 .}
  
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,it,fr" } .
  }
LIMIT 10
Try it! 
#Opere nalla collezione Certosa di Bologna - versione 2
SELECT DISTINCT ?item ?itemLabel ?itemDescription
WHERE {
  ?item wdt:P195/wdt:P361* wd:Q3671680
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,it,fr" } .
  }
Try it! 


#Sepolti in Certosa di Bologna con immagini della tomba nell'elemento wikidata
#Domanda: perché non posso selezionare image grid a sx in alto alla lista dei risultati?
SELECT DISTINCT ?item ?itemLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
  {
    SELECT DISTINCT ?item WHERE {
      ?item wdt:P119 wd:Q3671680.
      ?item p:P1442 ?statement0.
      ?statement0 (ps:P1442) _:anyValueP1442.
      
    }
    LIMIT 100
  }
}
Try it! 
#Liste des petits monuments ayant un lien vers des catégories de Commons (soit un lien de site ou P373)
SELECT ?item ?comm ?p373 ?cat WHERE {
  ?item wdt:P131* wd:Q1891.                               # ... municipality ...

  optional {?comm schema:about ?item ; schema:isPartOf <https://commons.wikimedia.org/> .}
  BIND(replace(wikibase:decodeUri(SUBSTR(STR(?comm), 45)),"_"," ") AS ?comm_decode)
   optional {?item wdt:P373 ?p373 .}
  
 bind(COALESCE(?comm_decode, ?p373) as ?cat) .
 VALUES ?trida { wd:Q1746392 wd:Q108325 wd:Q4989906 wd:Q10861631 wd:Q15077340 wd:Q1516537 wd:Q47008262 wd:Q179700}     # chapel, small monument, memorial, belltower, memorial monument, technical monument,  group of small monuments 
 ?item wdt:P31/wdt:P279* ?trida.                  #  small monument
  }
Try it! 


#Lista di biblioteche con coordinate geografiche e accessibili ai disabili
#defaultView:Map
SELECT ?biblioth_que ?coordonn_es_g_ographiques WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?biblioth_que (wdt:P31/(wdt:P279*)) wd:Q7075.
  OPTIONAL {  }
  OPTIONAL { ?biblioth_que wdt:P625 ?coordonn_es_g_ographiques. }
  
  
  ?biblioth_que wdt:P2846 wd:Q24192067.
  OPTIONAL {  }
}
LIMIT 100
Try it!

Tools

[edit]
#idem
SELECT DISTINCT ?item ?itemLabel ?statement1 WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
  {
    SELECT DISTINCT ?item WHERE {
      ?item p:P276 ?statement0.
      ?statement0 (ps:P276/(wdt:P279*)) wd:Q3671680.
      ?item p:P18 ?statement1.
      ?statement1 (ps:P18) _:anyValueP18.
    }
    LIMIT 100
  }
}
Try it!
Retrieved from "https://www.wikidata.org/w/index.php?title=User:Una_tantum&oldid=2275058432"