Excel INDIRECT

Function (Explained with

Examples + Video)
Excel INDIRECT Function –
Overview

The INDIRECT function in Excel can be used when you have the
reference of a cell or a range as a text string and you want to get the
values from those references.

In short – you can use the indirect formula to return the reference
specified by the text string.
 In this Excel tutorial, I will show you how to use the indirect function in
Excel using some practical examples.

But before I get into the examples, let’s first have a look at its syntax.

INDIRECT FUNCTION Syntax

=INDIRECT(ref_text, [a1])

Input Arguments
 ref_text – A text string that contains the reference to a cell or a named
range. This must be a valid cell reference, or else the function would
return a #REF! error
 [a1] – A logical value that specifies what type of reference to use
for ref text. This could either be TRUE (indicating A1 style reference) or
FALSE (indicating R1C1-style reference). If omitted, it is TRUE by
default.
Additional Notes
 INDIRECT is a volatile function. This means that it recalculates
whenever the excel workbook is open or whenever a calculation is
triggered in the worksheet. This adds to the processing time and slows
down your workbook. While you can use the indirect formula with small
datasets with little or no impact on the speed, you may see it making
your workbook slower when using it with large datasets
 The Reference Text (ref_text) could be:

o A reference to a cell that in-turn contains a reference in A1-style or

R1C1-style reference format.

o A reference to a cell in double-quotes.

o A named range that returns a reference

Examples of How to Use Indirect

Function in Excel
Now let’s dive in and have a look at some examples on how to use the
INDIRECT function in Excel.

Example 1: Use a Cell reference to Fetch

the Value
It takes the cell reference as a text string as input and returns the value
in that reference (as shown in the example below):

The formula in cell C1 is:

=INDIRECT("A1")

The above formula takes the cell reference A1 as the input argument
(within double quotes as a text string) and returns the value in this cell,
which is 123.
Now if you’re thinking, why don’t I simply use =A1 instead of using the
INDIRECT function, you have a valid question.

Here is why…

When you use =A1 or =$A$1, it gives you the same result. But when
you insert a row above the first row, you would notice that the cell
references would automatically change to account for the new row.

You can also use the INDIRECT function when you want to lock the cell
references in such a way that it does not change when you insert
rows/columns in the worksheet.

Example 2: Use Cell Reference in a Cell

to Fetch the Value
You can also use this function to fetch the value from a cell whose
reference is stored in a cell itself.

In the above example, cell A1 has the value 123.

Cell C1 has the reference to the cell A1 (as a text string).

Now, when you use the INDIRECT function and use C1 as the argument
(which in turn has a cell address as a text string in it), it would convert
the value in cell A1 into a valid cell reference.

This, in turn, means that the function would refer to cell A1 and return
the value in it.

Note that you don’t need to use double quotes here as the C1 has the
cell reference stored in the text string format only.

Also, in case the text string in cell C1 is not a valid cell reference, the
Indirect function would return the #REF! error.

Example 3: Creating a Reference Using

Value in a Cell
You can also create a cell reference using a combination of the column
alphabet and the row number.

For example, if cell C1 contains the number 2, and you use the
formula =INDIRECT(“A”&C1) then it would refer to cell A2.
A practical application of this could be when you want to create dynamic
reference to cells based on the value in some other cell.

In case the text string you use in the formula gives a reference that
Excel doesn’t understand, it will return the ref error (#REF!).

Example 4: Calculate the SUM of a Range

of Cells
You can also refer to a range of cells the same way you refer to a single
cell using the INDIRECT function in Excel.

For example, =INDIRECT(“A1:A5”) would refer to the range A1:A5.

You can then use the SUM function to find the total or the
LARGE/SMALL/MIN/MAX function to do other calculations.

Just like the SUM function, you can also use functions such as LARGE,
MAX/MIN, COUNT, etc.

Example 5: Creating Reference to a

Sheet Using the INDIRECT Function
 The above examples covered how to refer a cell in the same worksheet.
You can also use the INDIRECT formula to refer to a cell in some other
worksheet or another workbook as well.

Here is something you need to know about referring to other sheets:

  Let’s say you have a worksheet with the name Sheet1, and within the
sheet in the cell A1, you have the value 123. If you go to another sheet
(let’s say Sheet2) and refer to cell A1 in Sheet1, the formula would
be: =Sheet1!A1

But..

 If you have a worksheet that contains two or more than two words (with
a space character in between), and you refer to cell A1 in this sheet
from another sheet, the formula would be: =’Data Set’!A1

In case, of multiple words, Excel automatically inserts single quotation

marks at the beginning and end of the Sheet name.

Now let’s see how to create an INDIRECT function to refer to a cell in

another worksheet.

Suppose you have a sheet named Dataset and cell A1 in it has the value
123.

Now to refer to this cell from another worksheet, use the following
formula:

=INDIRECT("'Data Set'!A1")
As you can see, the reference to the cell needs to contain the worksheet
name as well.

If you have the name of the worksheet in a cell (let’s say A1), then you
can use the following formula:

=INDIRECT("'"&A1&"'!A1")

If you have the name of the worksheet in cell A1 and cell address in cell
A2, then the formula would be:

=INDIRECT("'"&A1&"'!"&A2)

Similarly, you can also modify the formula to refer to a cell in another
workbook.

This could be useful when you trying to create a summary sheet that
pulls the data from multiple different sheets.

Also remember, when using this formula to refer to another workbook,

that workbook must be open.

Example 6: Referring to a Named Range

Using INDIRECT Formula
 If you have created a named range in Excel, you can refer to that
named range using the INDIRECT function.

For example, suppose you have the marks for 5 students in three
subjects as shown below:

In this example, let’s name the cells:

 B2:B6: Math

 C2:C6: Physics

 D2:D6: Chemistry

To name a range of cells, simply select the cells and go to the name
box, enter the name and hit enter.

Now you can refer to these named ranges using the formula:
=INDIRECT("Named Range")

For example, if you want to know the average of the marks in Math, use
the formula:

=AVERAGE(INDIRECT("Math"))

If you have the named range name in a cell (F2 in the example below
has the name Math), you can use this directly in the formula.

The below example shows how to calculate the average using the
named ranges.

Example 7: Creating a Dependent Drop

Down List Using Excel INDIRECT Function
This is one excellent use of this function. You can easily create
a dependent drop-down list using it (also called the conditional drop-
down list).

For example, suppose you have a list of countries in a row and the name
of cities for each country as shown below:
 Now to create a dependent drop-down list, you need to create two
named ranges, A2:A5 with the name US and B2:B5 with the name
India.

Now select cell D2 and create a drop-down list for India and the US. This
would be the first drop-down list where the user gets the option to
select a country.

Now to create a dependent drop-down list:

 Select cell E2 (the cell in which you want to get the dependent drop-
down list).

 Click the Data tab

 Click on Data validation.

 Select List as the Validation Criteria and use the following formula in the
source field: =INDIRECT($D$2)

 Click OK.

Now, when you enter the US in cell D2, the drop-down in cell E2 will
show the states in the US.

And when you enter India in cell D2, the drop-down in cell E2 will show
the states in India.
 So these are some examples to use the INDIRECT function in Excel.
These examples would work on all the versions of Excel (Office 365,
Excel 2019/2016/2013/2013)

I hope you found this tutorial useful.

Related Microsoft Excel Functions:

 Excel VLOOKUP Function.
 Excel HLOOKUP Function.
 Excel INDEX Function.
 Excel MATCH Function.
 Excel OFFSET Function.
You May Also Like the Following Excel Tutorials:
 Excel Function Examples.
 Excel Function Reference.
 MS Excel Functions help – INDIRECT.
 200+ Excel Keyboard Shortcuts.
 Free Excel Templates.

10 VLOOKUP Examples
For Beginner & Advanced
Users + FREE EBOOK
 Home>>
 Blog>>
 Excel Functions>>
 10 VLOOKUP Examples For Beginner & Advanced Users + FREE EBOOK
This Tutorial Covers:
 1. VLOOKUP Function – Introduction

1. When to use the VLOOKUP Function in Excel?

2. Syntax

3. Input Arguments

4. Additional Notes (Boring, but important to know)

2. 10 Excel VLOOKUP Examples (Basic & Advanced)

1. Example 1 – Finding Brad’s Math Score

2. Example 2 – Two-Way Lookup

3. Example 3 – Using Drop Down Lists as Lookup Values

4. Example 4 – Three-way Lookup 

5. Example 5 – Getting the Last Value from a List

6. Example 6 – Partial Lookup using Wildcard Characters and VLOOKUP

7. Example 7 – VLOOKUP Returning an Error Despite a Match in Lookup Value

8. Example 8 – Doing a Case Sensitive Lookup

9. Example 9 – Using VLOOKUP with Multiple Criteria

10. Example 10 – Handling Errors while Using the VLOOKUP Function

3. Using VLOOKUP Function in Excel – Video

VLOOKUP Function – Introduction

VLOOKUP function is THE benchmark.

You know something in Excel if you know how to use the VLOOKUP
function.

If you don’t, you better not list Excel as one of your strong areas in your
resume.

I have been a part of the panel interviews where as soon as the

candidate mentioned Excel as his area of expertise, the first thing asked
was – you got it – the VLOOKUP function.
Now that we know how important this Excel function is, it makes sense
to ace it completely to be able to proudly say – “I know a thing or two in
Excel”.

This is going to be a massive VLOOKUP tutorial (by my standards).

I’ll cover everything there is to know about it, and then show you useful
and practical VLOOKUP examples.

So buckle up.

It’s time for the takeoff.

When to use the VLOOKUP Function in

Excel?
VLOOKUP function is best suited for situations when you are looking for
a matching data point in a column, and when the matching data point is
 found, you go to the right in that row and fetch a value from a cell which
is a specified number of columns to the right.

Let’s take a simple example here to understand when to use Vlookup in

Excel.

Remember when the exam score list was out and pasted on the notice
board and everyone used to go crazy finding their names and their score
(at least that’s what used to happen when I was in school).

Here is how it worked:

 You go up to the notice board and start looking for your name or enrolment
number (running your finger from top to bottom in the list).

 As soon as you spot your name, you move your eyes to the right of the
name/enrolment number to see your scores.

And that is exactly what the Excel VLOOKUP function does for you (feel
free to use this example in your next interview).

VLOOKUP function looks for a specified value in a column (in the above
example, it was your name) and when it finds the specified match, it
returns a value in the same row (the marks you obtained).

Syntax
=VLOOKUP(lookup_value, table_array, col_index_num, [range_lookup])

Input Arguments
 lookup_value – this is the look-up value you are trying to find in the left-
most column of a table. It could be a value, a cell reference, or a text string. In
the score sheet example, this would be your name.
 table_array – this is the table array in which you are looking for the value.
This could be a reference to a range of cells or a named range. In the score
sheet example, this would be the entire table that contains score for everyone
for every subject
 col_index – this is the column index number from which you want to fetch the
matching value. In the score sheet example, if you want the scores for Math
(which is the first column in a table that contains the scores), you’d look in
column 1. If you want the scores for Physics, you’d look in column 2.
 [range_lookup] – here you specify whether you want an exact match or an
approximate match. If omitted, it defaults to TRUE – approximate match (see
additional notes below).

Additional Notes (Boring, but important

to know)
 The match could be exact (FALSE or 0 in range_lookup) or approximate (TRUE
or 1).

 In approximate lookup, make sure that the list is sorted in ascending order
(top to bottom), or else the result could be inaccurate.

 When range_lookup is TRUE (approximate lookup) and data is sorted in

ascending order:

o If the VLOOKUP function can not find the value, it returns the largest value,

which is less than the lookup_value.

o It returns a #N/A error if the lookup_value is smaller than the smallest value.

o If lookup_value is text, wildcard characters can be used (refer to the example

below).
Now, hoping that you have a basic understanding of what the VLOOKUP
function can do, let’s peel this onion and see some practical examples of
the VLOOKUP function.

10 Excel VLOOKUP Examples (Basic

& Advanced)
Here are 10 useful exampels of using Excel Vlookup that will show you
how to use it in your day-to-day work.

Example 1 – Finding Brad’s Math Score

In the VLOOKUP example below, I have a list wth student names in the
left-most column and marks in different subjects in column B to E.

Now let’s get to work and use the VLOOKUP function for what it does
best. From the above data, I need to know how much Brad scored in
Math.

From the above data, I need to know how much Brad scored in Math.
 Here is the VLOOKUP formula that will return Brad’s Math score:

=VLOOKUP("Brad",$A$3:$E$10,2,0)

The above formula has four arguments:

 “Brad: – this is the lookup value.

 $A$3:$E$10 – this is the range of cells in which we are looking. Remember
that Excel looks for the lookup value in the left most column. In this example,
it would look for the name Brad in A3:A10 (which is the left-most column of
the specified array).
 2 – Once the function spots Brad’s name, it will go to the second column of the
array, and return the value in the same row as that of Brad. The value 2 here
indicated that we are looking for the score from the second column of the
specified array.
 0 – this tells the VLOOKUP function to only look for exact matches.

Here is how the VLOOKUP formula works in the above example.

First, it looks for the value Brad in the left-most column. It goes from
top to bottom and finds the value in cell A6.
As soon as it finds the value, it goes to the right in the second column
and fetches the value in it.

You can use the same formula construct to get anyone’s marks in any of
the subjects.

For example, to find Maria’s marks in Chemistry, use the following

VLOOKUP formula:

=VLOOKUP("Maria",$A$3:$E$10,4,0)
In the above example, the lookup value (student’s name) is entered in
double quotes. You can also use a cell reference that contains the
lookup value.

The benefit of using a cell reference is that it makes the formula

dynamic.

For example, if you have a cell with a student’s name, and you are
fetching the score for Math, the result would automatically update when
you change the student’s name (as shown below):

If you enter a lookup value that is not found in the left-most column, it
returns a #N/A error.

Example 2 – Two-Way Lookup

In Example 1 above, we hard-coded the column value. Hence, the
formula would always return the score for Math as we have used 2 as
the column index number.
But what if you want to make both the VLOOKUP value and the column
index number dynamic. For example, as shown below, you can change
either the student name or the subject name, and the VLOOKUP formula
fetches the correct score. This is an example of a two-way VLOOKUP
formula.

This is an example of a two-way VLOOKUP function.

To make this two-way lookup formula, you need to make the column
dynamic as well. So when a user changes the subject, the formula
automatically picks the correct column (2 in the case of Math, 3 in the
case of Physics, as so on..).

To do this, you need to use the MATCH function as the column

argument.

Here is the VLOOKUP formula that will do this:

=VLOOKUP(G4,$A$3:$E$10,MATCH(H3,$A$2:$E$2,0),0)
The above formula uses MATCH(H3,$A$2:$E$2,0) as the column
number. MATCH function takes the subject name as the lookup value (in
H3) and returns its position in A2:E2. Hence, if you use Math, it would
return 2 as Math is found in B2 (which is the second cell in the specified
array range).

Example 3 – Using Drop Down Lists as

Lookup Values
In the above example, we have to manually enter the data. That could
be time-consuming and error-prone, especially if you have a huge list of
lookup values.

A good idea in such cases is to create a drop-down list of the lookup

values (in this case, it could be student names and subjects) and then
simply choose from the list.

Based on the selection, the formula would automatically update the

result.

Something as shown below:

 This makes a good dashboard component as you can have a huge data
set with hundreds of students at the back end, but the end user (let’s
say a teacher) can quickly get the marks of a student in a subject by
simply making the selections from the drop down.

How to make this:

The VLOOKUP formula used in this case is the same used in Example 2.

=VLOOKUP(G4,$A$3:$E$10,MATCH(H3,$A$2:$E$2,0),0)

The lookup values have been converted into drop-down lists.

Here are the steps to create the drop down list:

 Select the cell in which you want the drop-down list. In this example, in G4, we
want the student names.

 Go to Data –> Data Tools –> Data Validation.

 In the Data Validation Dialogue box, within the settings tab, select List from
the Allow drop-down.

 In the source, select $A$3:$A$10

 Click OK.

Now you’ll have the drop-down list in cell G4. Similarly, you can create
one in H3 for the subjects.

Example 4 – Three-way Lookup 

What is a three-way lookup?
In Example 2, we’ve used one lookup table with scores for students in
different subjects. This is an example of a two-way lookup as we use
two variables to fetch the score (student’s name and the subject’s
name).

Now, suppose in a year, a student has three different levels of exams,

Unit Test, Midterm, and Final Examination (that’s what I had when I was
a student).

A three-way lookup would be the ability to get a student’s marks for a

specified subject from the specified level of exam.

Something as shown below:

In the above example, the VLOOKUP function can lookup in three
different tables (Unit Test, Midterm, and Final Exam) and returns the
score for the specified student in the specified subject.

Here is the formula used in cell H4:

=VLOOKUP(G4,CHOOSE(IF(H2="Unit Test",1,IF(H2="Midterm",2,3)),
$A$3:$E$7,$A$11:$E$15,$A$19:$E$23),MATCH(H3,$A$2:$E$2,0),0) 

This formula uses the CHOOSE function to make sure the right table is
referred to. Let’s analyze the CHOOSE part of the formula:

CHOOSE(IF(H2=”Unit Test”,1,IF(H2=”Midterm”,2,3)),
$A$3:$E$7,$A$11:$E$15,$A$19:$E$23)
The first argument of the formula is IF(H2=”Unit
Test”,1,IF(H2=”Midterm”,2,3)), which checks the cell H2 and see what
level of exam is being referred to. If it’s Unit Test, it returns $A$3:$E$7,
which has the scores for Unit Test. If it’s Midterm, it
returns $A$11:$E$15, else it returns $A$19:$E$23.

Doing this makes the VLOOKUP table array dynamic and hence makes it
a three-way lookup.

Example 5 – Getting the Last Value from

a List
You can create a VLOOKUP formula to get the last numerical value from
a list.
The largest positive number that you can use in Excel
is 9.99999999999999E+307. This also means that the
largest lookup number in the VLOOKUP number is also the same.

I don’t think you would ever need any calculation involving such a large
number. And that is exactly what we can use get the last number in a
list.

Suppose you have a dataset (in A1:A14) as shown below and you want
to get the last number in the list.

Here is the formula you can use:

=VLOOKUP(9.99999999999999E+307,$A$1:$A$14,TRUE)

Note that the formula above uses an approximate match

VLOOKUP (notice TRUE at the end of the formula, instead of FALSE or
0). Also, note that the list doesn’t need to be sorted for this VLOOKUP
formula to work.
 Here is how the approximate VLOOKUP function works. It scans the left
most column from top to bottom.

 If it finds an exact match, it returns that value.

 If it finds a value that is higher than the lookup value, it returns the value in
the cell above it.

 If the lookup value is greater than all the values in the list, it returns the last
value.

In the above example, the third scenario is at work.

Since 9.99999999999999E+307 is the largest number that can be

used in Excel, when this is used as the lookup value, it returns the last
number from the list.

In the same way, you can also use it to return the last text item from
the list. Here is the formula that can do that:

=VLOOKUP("zzz",$A$1:$A$8,1,TRUE)

The same logic follows. Excel looks through all the names, and since zzz
is considered bigger than any name/text starting with alphabets before
zzz, it would return the last item from the list.
Example 6 – Partial Lookup using
Wildcard Characters and VLOOKUP
Excel wildcard characters can be really helpful in many situations.

It’s that magic potion that gives your formulas super powers.

Partial look-up is needed when you have to look for a value in a list and
there isn’t an exact match.

For example, suppose you have a data set as shown below, and you
want to look for the company ABC in a list, but the list has ABC Ltd
instead of ABC.

You can not use ABC as the lookup value as there is no exact match in
column A. Approximate match also leads to erroneous results and it
requires the list to be sorted in an ascending order.

However, you can use a wildcard character within the VLOOKUP function

to get the match.

Enter the following formula in cell D2 and drag it to the other cells:

=VLOOKUP("*"&C2&"*",$A$2:$A$8,1,FALSE)
How does this formula work?
In the above formula, instead of using the lookup value as is, it is
flanked on both sides with the wildcard character asterisk (*)
– “*”&C2&”*”
An asterisk is a wildcard character in Excel and can represent any
number of characters.

Using the asterisk on both sides of the lookup value tells Excel that it
needs to look for any text that contains the word in C2. It could have
any number of characters before or after the text in C2.

For example, cell C2 has ABC, so the VLOOKUP function looks through
the names in A2:A8 and searches for ABC. It finds a match in cell A2, as
it contains ABC in ABC Ltd. It doesn’t matter if there are any characters
to the left or right of ABC. Until there is ABC in a text string, it will be
considered a match.

Note: VLOOKUP function always returns the first matching value and
stops looking further. So if you have ABC Ltd., and ABC Corporation in a
list, it will return the first one and ignore the rest.
Example 7 – VLOOKUP Returning an
Error Despite a Match in Lookup Value
It can drive you crazy when you see that there is a matching lookup
value and the VLOOKUP function is returning an error.

For example, in the below case, there is a match (Matt), but the
VLOOKUP function still returns an error.

Now while we can see there is a match, what we can not see with a
naked eye is that there could be leading or trailing spaces. If you have
these additional spaces before, after, or in between the lookup values, it
ISN’T an exact match.

This is often the case when you import data from a database or get it
from someone else. These leading/trailing spaces have a tendency to
sneak in.

The solution here is the TRIM function. It removes any leading or trailing

spaces or extra spaces between words.

Here is the formula that’ll give you the right result.

=VLOOKUP("Matt",TRIM($A$2:$A$9),1,0)
Since this is an array formula, use Control + Shift + Enter instead of
just Enter.

Another way could be to first treat your lookup array with the TRIM
function to make sure all the additional spaces are gone, and then use
the VLOOKUP function as usual.

Example 8 – Doing a Case Sensitive

Lookup
By default, the lookup value in the VLOOKUP function is not case
sensitive. For example, if your lookup value is MATT, matt, or Matt, it’s
all the same for the VLOOKUP function. It’ll return the first matching
value irrespective of the case.

But if you want to do a case-sensitive lookup, you need to use the

EXACT function along with the VLOOKUP function.

Here is an example:
As you can see, there are three cells with the same name (in A2, A4,
and A5) but with a different alphabet case.  On the right, we have the
three names (Matt, MATT, and matt) along with their scores in Math.

Now the VLOOKUP function is not equipped to handle case-sensitive

lookup values. In this above example, it would always return 38, which
is the score for Matt in A2.

To make it case sensitive, we need to use a helper column (as shown

below):

To get the values in the helper column, use the =ROW() function. It will
simply get the row number in the cell.

Once you have the helper column, here is the formula that will give the
case-sensitive lookup result.

=VLOOKUP(MAX(EXACT(E2,$A$2:$A$9)*(ROW($A$2:$A$9))),$B$2:$C$9,2,0)

Now let’s break down and understand what this does:

 EXACT(E2,$A$2:$A$9) – This part would compare the lookup value in E2 with
all the values in A2:A9. It returns an array of TRUEs/FALSEs where TRUE is
returned where there is an exact match. In this case, it would return the
following array: {TRUE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE}.
 EXACT(E2,$A$2:$A$9)*(ROW($A$2:$A$9) – This part multiplies the array of
TRUEs/FALSEs with the row number. Wherever there is a TRUE, it gives the
row number, else it gives 0. In this case, it would return {2;0;0;0;0;0;0;0}.
 MAX(EXACT(E2,$A$2:$A$9)*(ROW($A$2:$A$9))) – This part returns the
maximum value from the array of numbers. In this case, it would return 2
(which is the row number where there is an exact match).
 Now we simply use this number as the lookup value and use the lookup array
as B2:C9

Note: Since this is an array formula, use Control + Shift + Enter instead
of just enter.
Example 9 – Using VLOOKUP with
Multiple Criteria
Excel VLOOKUP function, in its basic form, can look for one lookup value
and return the corresponding value from the specified row.

But often there is a need to use VLOOKUP in Excel with multiple criteria.

Suppose you have a data with students name, exam type, and the Math
score (as shown below):
Using the VLOOKUP function to get the Math score for each student for
respective exam levels could be a challenge.

For example, if you try using VLOOKUP with Matt as the lookup value,
it’ll always return 91, which is the score for the first occurrence of Matt
in the list. To get the score for Matt for each exam type (Unit Test, Mid
Term and Final), you need to create a unique lookup value.

This can be done using the helper column. The first step is to insert a
helper column to the left of the scores.
Now, to create a unique qualifier for each instance of the name, use the
following formula in C2: =A2&”|”&B2

Copy this formula to all the cells in the helper column. This will create
unique lookup values for each instance of a name (as shown below):
Now, while there were repetitions of the names, there is no repetition
when the name is combined with the level of examination.

This makes it easy as now you can use the helper column values as the
lookup values.

Here is the formula that’ll give you the result in G3:I8.

=VLOOKUP($F3&"|"&G$2,$C$2:$D$19,2,0)

Here we have combined the student name and the level of examination
to get the lookup value, and we use this lookup value and checks it in
the helper column to get the matching record.
Note: In the above example, we have used | as the separator while
joining text in the helper column. In some exceptionally rare (but
possible) conditions, you may have two criteria that are different but
ends up giving the same result when combined. Here is an example:

Note that while A2 and A3 are different and B2 and B3 are different, the
combinations end up being the same. But if you use a separator, then
even the combination would be different (D2 and D3).

Here is a tutorial on how to use VLOOKUP with multiple criteria without

using helper columns. You can also watch my video tutorial here.
Example 10 – Handling Errors while
Using the VLOOKUP Function
Excel VLOOKUP function returns an error when it can not find the
specified lookup value. You may not want the ugly error value disturbing
the aesthetics of your data in case VLOOKUP can’t find a value.

You can easily remove the error values with any meaning full text such
as “Not Available” or “Not Found”.

For example, in the example below, when you try to find the score of
Brad in the list, it returns an error as Brad’s name is not there in the list.

To remove this error and replace it with something meaningful, wrap

your VLOOKUP function within the IFERROR function.

Here is the formula:

=IFERROR(VLOOKUP(D2,$A$2:$B$7,2,0),"Not Found")
The IFERROR function checks if the value returned by the first argument
(which is the VLOOKUP function in this case) is an error or not. If it’s not
an error, it returns the value by the VLOOKUP function, else it
returns Not Found.

IFERROR function is available from Excel 2007 onwards. If you are using
versions prior to that, use the following function:

=IF(ISERROR(VLOOKUP(D2,$A$2:$B$7,2,0)),"Not
Found",VLOOKUP(D2,$A$2:$B$7,2,0))

Also See: How to handle VLOOKUP Errors in Excel.

That’s it in this VLOOKUP tutorial.

I’ve tried to cover major examples of using the Vlookup function in

Excel. If you would like to see more examples added to this list, let me
know in the comments section.

Note: I’ve tried my best to proof read this tutorial, but in case you find
any errors or spelling mistakes, please let me know 🙂