User:YanikB

This user loves OpenRefine.

fr-N	Cet utilisateur a pour langue maternelle le français.

en-3	This user has advanced knowledge of English.

es-2	Esta persona tiene un conocimiento intermedio del español.

de-1	Dieser Benutzer beherrscht Deutsch auf grundlegendem Niveau.

Welcome

For a detailed presentation, read my Wikipedia user page

Bienvenu

Pour une présentation détaillée lisez ma page sur Wikipédia

Ressources

Description du code

?item p:P39 [ps:P39 wd:Q90265261 ; pq:P585  ?date] 
# p: développe la déclaration P39 ; on utilise souvent wdt: à la place mais ça ne récupère que la valeur principale.
# ps: récupère la valeur principale de cette déclaration, aussi avec P39 c’est redondant.
# pq: récupère la valeur d’un qualificatif (ici date) entre les crochets on a accès à tout ce qui concerne la déclaration^[1].

↑ Gracieuseté de User:TomT0m

SELECT DISTINCT ('Q176' as ?qid) (?pmqid as ?P6) (?position as ?qal1545) (?debut as ?qal580) (?fin as ?qal582) ?pmLabel
WHERE { 
  ?pm p:P39 ?statement .                                    # fonction
  ?statement ps:P39 wd:Q2911019 .                           # permier ministre du Québec
  OPTIONAL { ?statement pq:P1545 ?position }                # numéro
  OPTIONAL {
    ?statement pqv:P580 [wikibase:timeValue ?dt; wikibase:timePrecision ?dp] .
    FILTER STRENDS(?dt, 'Z') .
    BIND(CONCAT('+', STR(?dt), '/', STR(?dp)) as ?debut) .  # format date Quickstatement
  }
  OPTIONAL { 
    ?statement pqv:P582 [wikibase:timeValue ?ft; wikibase:timePrecision ?fp] .
    FILTER STRENDS(?ft, 'Z') .
    BIND(CONCAT('+', STR(?ft), '/', STR(?fp)) as ?fin) .
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en". }
}
ORDER BY ?debut

Try it!

Modèles

Template:ValidAtDate

Nomenclature

Seigneurie : Saint-Antoine-de-la-Baie-du-Febvre (Q24847894)

Outils

OpenRefine

Service en https://wikidata.reconci.link/en/api
Service fr https://wikidata.reconci.link/fr/api

Avancements

Rivières sur l'île d'Anticosti

SELECT DISTINCT ?id ?idLabel ?long ?geo ?geo2
WHERE {
  ?id wdt:P31 wd:Q4022 .                
  ?id wdt:P706 wd:Q575033.
  ?id wdt:P625 ?geo .
  {?id p:P625 [ ps:P625 ?geo; pq:P518 ?appl ] }
  OPTIONAL {?id p:P625 [ ps:P625 ?geo ] }
  FILTER (?appl != wd:Q7376362).  
  {?id p:P625 [ ps:P625 ?geo2; pq:P518 ?cren ] }
  OPTIONAL {?id p:P625 [ ps:P625 ?geo2] }
  FILTER (?cren = wd:Q7376362).
  OPTIONAL {?id wdt:P2043 ?long }
#  OPTIONAL {?id wdt:P402 ?osm }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "fr,en" . }
  OPTIONAL {
            ?link schema:about ?id .
            ?link schema:isPartOf <https://fr.wikipedia.org/> .
            ?link schema:name ?title.
  }
}

Try it!

Municipalités du Québec sans gentilé

Municipalités du Québec sans gentilé.

SELECT DISTINCT ?item ?itemLabel  
  WHERE {
         {?item wdt:P31/wdt:P279* wd:Q3327873} 
         ?item wdt:P131 ?mrc .
         ?mrc wdt:P131 ?region          
         FILTER (?region = wd:Q809729) .
         OPTIONAL { ?item wdt:P1549 ?gent }    
         FILTER NOT EXISTS {?item wdt:P1549 ?gent }
         FILTER NOT EXISTS { ?item wdt:P582 ?enddt . }
         FILTER NOT EXISTS { ?item wdt:P576 ?dissoldt . } 
         SERVICE wikibase:label { bd:serviceParam wikibase:language 'en,fr'. } .
 }
ORDER BY ?code
LIMIT 300

Try it!

Communautés autochtones au Québec

# Réserves indiennes au Québec.
SELECT DISTINCT ?item ?itemLabel ?link
WHERE {
      {?item wdt:P31/wdt:P279* wd:Q688718}
      ?item wdt:P31 ?nature .
       FILTER (?nature = wd:Q81064299) .
       SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en" }
       OPTIONAL {?link schema:about ?item .
                 ?link schema:isPartOf <https://fr.wikipedia.org/> . }
}
order by ?itemLabel
LIMIT 100

Try it!

Rivières du bassin de la baie d'Hudson sans article sur WP:fr

# Rivières du bassin versant de la baie d'Hudson
SELECT Distinct ?id ?idLabel ?Longueur ?ConfluenceLabel ?BassinLabel ?OSM WHERE { 
  ?id wdt:P31 wd:Q4022 .
  { ?id (wdt:P403|wdt:P201)* wd:Q3040 } # Pour une double vérification déplacez le # sur la ligne suivante.
#  {?id wdt:P4614* wd:Q14874626} 
  OPTIONAL { ?id wdt:P403 ?Confluence }
  OPTIONAL {?id wdt:P2043 ?Longueur }
#  filter  (?Longueur >10) .
  OPTIONAL {
            ?Lien schema:about ?id .
            ?Lien schema:isPartOf <https://fr.wikipedia.org/> .
  }
  filter not exists { ?Lien schema:about ?id .
            ?Lien schema:isPartOf <https://fr.wikipedia.org/> . }
  OPTIONAL {?id wdt:P4614 ?Bassin }
  OPTIONAL {?id wdt:P402 ?OSM }
#  filter not exists { ?id wdt:P402 ?OSM }
#  OPTIONAL {?id wdt:P31 ?nature }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "fr,en" . }
}
order by  DESC(?Longueur)

Try it!

Rivières du bassin de l'Harricana

# Bassin de l'Harricana
SELECT Distinct ?id ?idLabel ?longueur ?affluentLabel ?riveLabel ?natureLabel ?lien 
WHERE {  
  {?id wdt:P4614* wd:Q70205427}
  ?id wdt:P403 ?affluent.
  ?id wdt:P2043 ?longueur .
  Optional { ?id wdt:P3871 ?rive }
  ?id wdt:P31 ?nature .
#  filter (?nature != wd:Q63565252) .
  filter  (?longueur > 15) .
# ?id wdt:P402 ?osm .
  SERVICE wikibase:label {bd:serviceParam wikibase:language "fr,en" . }
  OPTIONAL {
            ?lien schema:about ?id .
            ?lien schema:isPartOf <https://fr.wikipedia.org/> .
  }
}
order by ?affluentLabel

Try it!

Rivières du bassin de la Rupert

#Rivières du bassin de la Rupert
SELECT Distinct ?id ?idLabel ?confluentLabel ?long ?link  WHERE {  
#  { ?id (wdt:P403|wdt:P201)* wd:Q427437} # Double vérification
  {?id wdt:P4614* wd:Q115301609}
  ?id wdt:P31 wd:Q4022 .
  ?id wdt:P403 ?confluent .
  Optional { ?id wdt:P2043 ?long }
#  filter  (?long >20) .
#  filter not exists { ?id wdt:P402 ?osm }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "fr,en" . }
  OPTIONAL {
            ?link schema:about ?id .
            ?link schema:isPartOf <https://fr.wikipedia.org/> .
  }
}
order by  DESC(?long)

Try it!

Rivières du bassin versant de la rivière baie James

#Rivières du bassin versant de la baie James
SELECT Distinct ?id ?idLabel ?bassinLabel ?long ?link ?natLabel WHERE {  
  { ?id (wdt:P403|wdt:P201)* wd:Q223810 }
  ?id wdt:P31 ?nat .
#  ?id wdt:P31 wd:Q4022 .
  OPTIONAL {?id wdt:P4614 ?bassin }
  OPTIONAL {?id wdt:P2043 ?long }
  filter  (?long >10) .
  SERVICE wikibase:label {bd:serviceParam wikibase:language "fr,en" . }
  OPTIONAL {
            ?link schema:about ?id .
            ?link schema:isPartOf <https://fr.wikipedia.org/> .
  }
}
order by  ?idLabel

Try it!

Rivières du bassin de la Nottaway

# Rivières du bassin de la Nottaway
SELECT DISTINCT ?id ?title ?idLabel ?len ?confluenceLabel ?oriLabel ?geo ?loc1Label ?geo2 ?loc2Label  WHERE {  
  {?id wdt:P4614* wd:Q47004199} # Bassin de la Nottaway
  ?id wdt:P31 wd:Q4022 .        # Rivière
  ?id wdt:P403 ?confluence .
  ?id wdt:P625 ?geo .
  OPTIONAL {?id wdt:P3871 ?ori}
  {?id p:P625 [ ps:P625 ?geo; pq:P518 ?appl ] }
  OPTIONAL {?id p:P625 [ ps:P625 ?geo; pq:P131 ?loc1 ] }
  FILTER (?appl != wd:Q7376362).  
  {?id p:P625 [ ps:P625 ?geo2; pq:P518 ?cren ] }
  OPTIONAL {?id p:P625 [ ps:P625 ?geo2; pq:P131 ?loc2 ] }
  FILTER (?cren = wd:Q7376362).
  OPTIONAL {?id wdt:P2043 ?len }
  OPTIONAL {?id wdt:P402 ?osm }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "fr,en" . }
  OPTIONAL {
            ?link schema:about ?id .
            ?link schema:isPartOf <https://fr.wikipedia.org/> .
            ?link schema:name ?title.
  }
}

ORDER BY ?idLabel

Try it!

Lac sans drainage basin (P4614)

# Bassin versant d'un lac ayant un émissaire.
SELECT DISTINCT ?item ?itemLabel ?bassLabel ?confLabel ?locLabel
WHERE
{
    ?item wdt:P201 ?emis .
    ?item wdt:P31 wd:Q23397 .
    ?item wdt:P131 ?loc .
    ?emis wdt:P403 ?conf .
    ?emis wdt:P4614* wd:Q28031866 .     # bassin du Saint-Maurice
    ?emis wdt:P4614 ?bass .
    FILTER NOT EXISTS { ?item wdt:P4614 ?bassin }
    SERVICE wikibase:label {
            bd:serviceParam wikibase:language "fr,en" 
    }
}
ORDER BY (?itemLabel) 
LIMIT 5000

Try it!

Rivières du Québec sans longueur

#Rivières du Québec sans longueur
SELECT Distinct ?id ?idLabel ?link WHERE {  
  ?id wdt:P31 wd:Q4022 .
  OPTIONAL {?id wdt:P2043 ?long }
  ?id wdt:P131 ?region .
  ?region wdt:P131* wd:Q176 . 
  filter not exists {?id wdt:P2043 ?long }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "fr,en" . }
   {
            ?link schema:about ?id .
            ?link schema:isPartOf <https://fr.wikipedia.org/> .
  }
}
order by  ?idLabel

Try it!

Rivières du bassin de la Baie d'Hudson sans identifiant OSM

#Rivières du bassin de la Baie d'Hudson sans identifiant OSM 
SELECT Distinct ?id ?idLabel ?confluentLabel ?long ?natureLabel ?link  WHERE {  
  {?id wdt:P4614* wd:Q14874626}
  ?id wdt:P403 ?confluent.
  ?id wdt:P2043 ?long .
  ?id wdt:P31 ?nature .
  FILTER (?long >10) .
  FILTER (?nature != wd:Q63565252) .
  FILTER NOT EXISTS { ?id wdt:P402 ?osm }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "fr,en" . }
  OPTIONAL {
            ?link schema:about ?id .
            ?link schema:isPartOf <https://fr.wikipedia.org/> .
  }
}
order by  DESC(?long)

Try it!

Affluents de l'Amazone

# Affluents de l'Amazone.
SELECT DISTINCT ?id ?title ?idLabel ?len ?oriLabel ?geo ?loc1 ?geo2 ?loc2 WHERE {  
  {?id wdt:P403 wd:Q3783} 
  ?id wdt:P625 ?geo .
  OPTIONAL {?id wdt:P3871 ?ori}
  {?id p:P625 [ ps:P625 ?geo; pq:P518 ?appl ] }
  OPTIONAL {?id p:P625 [ ps:P625 ?geo; pq:P131 ?loc1 ] }
  FILTER (?appl != wd:Q7376362).  
  {?id p:P625 [ ps:P625 ?geo2; pq:P518 ?cren ] }
  OPTIONAL {?id p:P625 [ ps:P625 ?geo2; pq:P131 ?loc2 ] }
  FILTER (?cren = wd:Q7376362).
  OPTIONAL {?id wdt:P2043 ?len }
  OPTIONAL {?id wdt:P4614 ?bass }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "fr,en" . }
  OPTIONAL {
            ?link schema:about ?id .
            ?link schema:isPartOf <https://en.wikipedia.org/> .
            ?link schema:name ?title.
  }
}
ORDER BY ?idLabel

Try it!

Affluents du Missouri

# Affluents du Missouri .
SELECT DISTINCT ?id ?title ?idLabel ?len ?oriLabel ?geo ?loc1 ?geo2 ?loc2 WHERE {  
  {?id wdt:P403 wd:Q5419} 
  ?id wdt:P625 ?geo .
  OPTIONAL {?id wdt:P3871 ?ori}
  {?id p:P625 [ ps:P625 ?geo; pq:P518 ?appl ] }
  OPTIONAL {?id p:P625 [ ps:P625 ?geo; pq:P131 ?loc1 ] }
  FILTER (?appl != wd:Q7376362).  
  {?id p:P625 [ ps:P625 ?geo2; pq:P518 ?cren ] }
  OPTIONAL {?id p:P625 [ ps:P625 ?geo2; pq:P131 ?loc2 ] }
  FILTER (?cren = wd:Q7376362).
  OPTIONAL {?id wdt:P2043 ?len }
  OPTIONAL {?id wdt:P4614 ?bass }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "fr,en" . }
  OPTIONAL {
            ?link schema:about ?id .
            ?link schema:isPartOf <https://en.wikipedia.org/> .
            ?link schema:name ?title.
  }
}
ORDER BY ?idLabel

Try it!

Affluents du Mississippi

# Affluents du Mississippi.
SELECT DISTINCT ?id ?title ?idLabel ?len ?oriLabel ?geo ?loc1 ?geo2 ?loc2 WHERE {  
  {?id wdt:P403 wd:Q1497} 
  ?id wdt:P625 ?geo .
  OPTIONAL {?id wdt:P3871 ?ori}
  {?id p:P625 [ ps:P625 ?geo; pq:P518 ?appl ] }
  OPTIONAL {?id p:P625 [ ps:P625 ?geo; pq:P131 ?loc1 ] }
  FILTER (?appl != wd:Q7376362).  
  {?id p:P625 [ ps:P625 ?geo2; pq:P518 ?cren ] }
  OPTIONAL {?id p:P625 [ ps:P625 ?geo2; pq:P131 ?loc2 ] }
  FILTER (?cren = wd:Q7376362).
  OPTIONAL {?id wdt:P2043 ?len }
  OPTIONAL {?id wdt:P4614 ?bass }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "fr,en" . }
  OPTIONAL {
            ?link schema:about ?id .
            ?link schema:isPartOf <https://en.wikipedia.org/> .
            ?link schema:name ?title.
  }
}
ORDER BY ?idLabel

Try it!

Personnalités mortes de la Covid-19 par pays par années

# Personnalités mortes de la Covid-19
SELECT ?paysLabel (COUNT(?item) AS ?count)
WHERE{
  ?item wdt:P509 wd:Q84263196 ; wdt:P27 ?pays ; wikibase:sitelinks ?sitelinks .
  ?item wdt:P570 ?time0 .
  FILTER((?time0 >= "2020-01-01T00:00:00Z"^^xsd:dateTime) && (?time0 <= "2023-01-01T00:00:00Z"^^xsd:dateTime))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr". }
  minus{ ?pays wdt:P576 [].}
  FILTER (?sitelinks >= 1) .
}
GROUP BY ?paysLabel
ORDER BY DESC(?count)

Try it!

Longueur totale des rivières au Québec (J'ai tracé 75K km sur le résultat)

# Longueur totale des rivières au Québec.
SELECT DISTINCT (sum(?longueur) as ?total_longueur) 
WHERE {
  ?item wdt:P17 wd:Q16 .
  ?item wdt:P31 wd:Q4022.
  ?item wdt:P131 ?region .
  ?region wdt:P131* wd:Q176 .  
  ?item wdt:P2043 ?longueur . 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr". }
}

Try it!

Rivières du Québec ayant plusieurs mouth of the watercourse (P403)

#Rivières du Québec ayant plusieurs propriété P403
SELECT ?item (COUNT(?item) as ?count) 
WHERE
{
  ?item (wdt:P31) wd:Q4022.
  ?item wdt:P131* wd:Q176.
  ?item (wdt:P403) ?déverse.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en". }
}
GROUP BY ?item
HAVING (?count > 1)
LIMIT 500

Try it!

Tributaires de la baie d'Ungava

# Tributaires de la baie d'Ungava.
SELECT DISTINCT ?id ?idLabel ?titre ?confluentLabel ?long ?locLabel ?loc1Label ?geo ?geo2 ?loc2Label WHERE {  
  {?id wdt:P403* wd:Q1165951} 
  ?id wdt:P403 ?confluent .
  ?id wdt:P625 ?geo .
  ?id wdt:P131 ?loc .
  {?id p:P625 [ ps:P625 ?geo; pq:P518 ?appl ] }
  OPTIONAL {?id p:P625 [ ps:P625 ?geo; pq:P131 ?loc1 ] }
  FILTER (?appl != wd:Q7376362).  
  {?id p:P625 [ ps:P625 ?geo2; pq:P518 ?cren ] }
  OPTIONAL {?id p:P625 [ ps:P625 ?geo2; pq:P131 ?loc2 ] }
  FILTER (?cren = wd:Q7376362).
  OPTIONAL {?id wdt:P2043 ?long }
  OPTIONAL {?id wdt:P4614 ?bass }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "fr,en" . }
  OPTIONAL {
            ?link schema:about ?id .
            ?link schema:isPartOf <https://fr.wikipedia.org/> .
            ?link schema:name ?titre.
  }
}
ORDER BY ?idLabel

Try it!

Rivières du bassin des Outaouais sans article

# rivières du bassin des Outaouais.
SELECT DISTINCT ?item ?idLabel ?confLabel ?long
WHERE 
{
  ?item (wdt:P4614*) wd:Q28163348.
  ?item (wdt:P31) wd:Q4022.
  BIND( ?item as ?id )
  OPTIONAL { ?id wdt:P403 ?conf }
  OPTIONAL { ?id wdt:P2043 ?long }
    SERVICE wikibase:label {
		bd:serviceParam wikibase:language "fr,en" .
	}
    FILTER NOT EXISTS {
    [] schema:about ?item ;
             schema:isPartOf <https://fr.wikipedia.org/> .
  }
} 
LIMIT 100

Try it!

Cours d'eau du bassin du lac Saint-Pierre sans crénon

SELECT ?item (COUNT(?item) as ?count) 
WHERE
{
  ?item (wdt:P4614*) wd:Q50375272.
  ?item (wdt:P31) wd:Q4022.
  {?item p:P625 [ ps:P625 ?geo1; pq:P518 ?appl ] }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en". }
}
GROUP BY ?item
HAVING (?count < 2)
LIMIT 100

Try it!

Cours d'eau du bassin du lac Saint-Pierre

SELECT DISTINCT ?item ?itemLabel ?geo1 ?loc1Label ?geo2 ?loc2Label ?long WHERE {
  ?item (wdt:P4614*) wd:Q50375272.
  ?item (wdt:P31) wd:Q4022.
  optional {?item (wdt:P403) ?conf.}
    FILTER (?conf != wd:Q134750 )
  optional {?item wdt:P2043 ?long }
  optional {?item p:P625 [ ps:P625 ?geo1; pq:P131 ?loc1 ] }
  optional {?item p:P625 [ ps:P625 ?geo1; pq:P518 ?appl1 ] }
    FILTER (?appl1 != wd:Q7376362 )
  optional {?item p:P625 [ ps:P625 ?geo2; pq:P131 ?loc2 ] }
  optional {?item p:P625 [ ps:P625 ?geo2; pq:P518 ?appl2 ] }
    FILTER (?appl2 = wd:Q7376362 )
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en" }
}
LIMIT 150

Try it!

Estimation de population 2021 des MRC

SELECT DISTINCT ?locLabel (SUM(?population) AS ?totalPopulation)
WHERE {
       {?item wdt:P31/wdt:P279* wd:Q3327873} UNION {?item wdt:P31 wd:Q81066200}
       ?item p:P1082 [ ps:P1082 ?population; pq:P459 wd:Q29051383; pq:P585 ?date ] .
       FILTER (?date  >= "2020-07-01T00:00:00Z"^^xsd:dateTime )
       ?item wdt:P131 ?loc.
       SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en" }
}
GROUP BY ?locLabel 
LIMIT 1500

Try it!

Estimation de population 2021 des régions

SELECT DISTINCT ?locationLabel (SUM(?population) AS ?totalPopulation)
WHERE {
       {?item wdt:P31 wd:Q104782082} union {?item wdt:P31 wd:Q204613}
       {?item p:P1082 [ ps:P1082 ?population; pq:P459 wd:Q29051383; pq:P585 ?date ] }
       FILTER (?date  >= "2020-07-01T00:00:00Z"^^xsd:dateTime )
       ?item wdt:P131 ?loc .
       ?loc wdt:P31 ?nat .
       ?loc wdt:P131 ?loc2 .
       FILTER (?nat = wd:Q55998242 || ?nat = wd:Q2826814 )
       BIND(IF(?nat = wd:Q2826814,?loc2,?loc ) as ?location) 
       SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en" }
  }
GROUP BY ?locationLabel 
LIMIT 1500

Try it!

Chenal au Québec

SELECT DISTINCT ?id  ?idLabel ?locLabel ?coord 
WHERE
{
    ?id wdt:P31/wdt:P279* wd:Q1210950 .
    ?id wdt:P17 wd:Q16 .
    ?id wdt:P131 ?region .
    ?region wdt:P131* wd:Q176 .
    ?id wdt:P131 ?loc .
    OPTIONAL {?id wdt:P625 ?coord }
    SERVICE wikibase:label {
            bd:serviceParam wikibase:language "fr,en" 
    }
}
ORDER BY (?idLabel) 
LIMIT 500

Try it!

Affluent de l'estuaire sans identifiant OSM

SELECT DISTINCT ?id ?idLabel ?estuaireLabel
WHERE
{
    ?id wdt:P4614 wd:Q51885235 .
    ?id wdt:P31/wdt:P279* wd:Q355304 .
    OPTIONAL { ?id p:P4614 [ pq:P518 ?estuaire ] } 
    filter not exists { ?id wdt:P402 ?osm }
    SERVICE wikibase:label {
            bd:serviceParam wikibase:language "fr,en" 
    }
}
ORDER BY (?idLabel) 
LIMIT 500

Try it!

Maj identifiant OSM

SELECT Distinct ?id ?idLabel ?confluentLabel ?long ?geo ?link WHERE {  
  {?id wdt:P403* wd:Q392161} Union {?id wdt:P403* wd:Q979922} Union {?id wdt:P403* wd:Q1471254}            # se jette dans le Saguenay
  ?id wdt:P403 ?confluent .
  ?id wdt:P625 ?geo .
  ?id wdt:P2043 ?long .
  filter not exists { ?id wdt:P402 ?osm }
#  BIND (xsd:integer (?osm) as ?nosm )
  SERVICE wikibase:label {bd:serviceParam wikibase:language "fr,en" . }
   {
            ?link schema:about ?id .
            ?link schema:isPartOf <https://fr.wikipedia.org/> .
  }
}
#order by ?nosm

Try it!

Affluent du Saint-Laurent sans longueur

SELECT DISTINCT ?item ?itemLabel ?bassinLabel ?estuaireLabel
WHERE
{
    ?item wdt:P4614/wdt:P361* wd:Q48983740 . # Bassin du fleuve Saint-Laurent
    ?item wdt:P31/wdt:P279* wd:Q355304 .
    ?item wdt:P4614 ?bassin .
    OPTIONAL { ?item p:P4614 [ pq:P518 ?estuaire ] } 
    FILTER NOT EXISTS { ?item wdt:P2043 ?long }
    SERVICE wikibase:label {
            bd:serviceParam wikibase:language "fr,en" 
    }
}
ORDER BY (?itemLabel) 
LIMIT 700

Try it!

4 MRC sans URL officiel

SELECT DISTINCT ?municip ?link ?municipLabel ?dateCreation ?superficie ?regionLabel  
WHERE 
{   # MRC sans URL officiel
    {?municip wdt:P31*/wdt:P279* wd:Q204613 }  
    ?municip wdt:P31 ?statut .
    ?municip wdt:P131 ?region .
    ?region wdt:P131 wd:Q176 .
    Optional {?municip wdt:P571 ?dateCreation }
    Optional {?municip wdt:P2046 ?superficie }
    Optional {?municip wdt:P856 ?url }
    FILTER NOT EXISTS { ?municip wdt:P856 ?url }
    FILTER NOT EXISTS { ?municip wdt:P576 ?dissolu}
    FILTER NOT EXISTS { ?municip wdt:P582 ?fin }
    FILTER NOT EXISTS { ?municip p:P31 [ pq:P582 ?pqfin ] }
    SERVICE wikibase:label {
		bd:serviceParam wikibase:language "fr,en" .
	}
    OPTIONAL {
            ?link schema:about ?municip .
            ?link schema:isPartOf <https://fr.wikipedia.org/> }
} 
ORDER BY ?regionLabel ?municip
LIMIT 1000

Try it!

Personnalité inhumée au cimetière Mont-Royal‎

SELECT DISTINCT ?item ?nomLabel ?itemLabel ?itemDescription ?dtnaissance ?lieunaisLabel ?dtdeces ?lieudecesLabel
WHERE
{
    ?item wdt:P119 wd:Q1457377 .
    OPTIONAL {?item wdt:P734 ?nom }
    OPTIONAL {?item p:P569 [ps:P569 ?dtnaissance; psv:P569 [wikibase:timePrecision ?precDoB] ] }
    ?month wdt:P31 wd:Q47018901; wdt:P279 wd:Q18602249; wdt:P1545 ?monthnumber . FILTER(?monthnumber=STR(MONTH(?dtnaissance)))
    ?month rdfs:label ?monthname . FILTER(lang(?monthname)='fr')
    BIND(IF(?precDoB=11,?dtnaissance,IF(?precDoB=10,CONCAT(STR(?monthname),' ',STR(YEAR(?dtnaissance))),YEAR(?dtnaissance))) AS ?dtnaissance)  
    OPTIONAL {?item wdt:P19 ?lieunais }
    OPTIONAL {?item wdt:P570 ?dtdeces }
    OPTIONAL {?item wdt:P20 ?lieudeces }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr" }
}
ORDER BY (?nomLabel)

Try it!

Quartiers de référence de Montréal : 98%

SELECT ?id ?no ?idLabel ?link ?ArrondissementLabel ?population ?geo WHERE     
{
  ?id wdt:P31 wd:Q123705 .               # Quartier
  ?id wdt:P131* wd:Q340 .                # Ville de Montréal
  ?id wdt:P131 ?Arrondissement .
  OPTIONAL {?id p:P31 [ pq:P1545 ?no ]}
  OPTIONAL {?id wdt:P1545 ?no}
  OPTIONAL {?id wdt:P1082 ?population }
  OPTIONAL {?id wdt:P625 ?geo }
  FILTER NOT EXISTS { ?id wdt:P31 wd:Q22674925 }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "fr,en" . }
  OPTIONAL {
            ?link schema:about ?id .
            ?link schema:isPartOf <https://fr.wikipedia.org/> .
  }
}
ORDER BY ?no

Try it!

Affluents et sous-affluent du Saint-Laurent sans drainage basin (P4614)

# Affluents et sous-affluent du Saint-Laurent 
SELECT DISTINCT ?id ?idLabel ?municipLabel ?mrcLabel ?regionLabel  
WHERE 
{
    ?id wdt:P31 wd:Q4022 .
    ?id wdt:P403* wd:Q134750 .
    ?id wdt:P131 ?municip .
    ?municip wdt:P131 ?mrc .
    ?mrc wdt:P131* wd:Q176 .
    ?mrc wdt:P131 ?region .
    FILTER NOT EXISTS { ?id wdt:P4614 ?bassin }
    SERVICE wikibase:label {
		bd:serviceParam wikibase:language "fr,en" .
	}
} 
ORDER BY ?regionLabel ?mrcLabel ?municipLabel
LIMIT 500

Try it!

Cours d'eau du bassin de l'estuaire du Saint-Laurent sans identifiant CTQ

# Cours d'eau du bassin de l'estuaire du Saint-Laurent
SELECT DISTINCT ?id ?idLabel ?municipLabel ?mrcLabel ?regionLabel  
WHERE 
{
    ?id wdt:P31/wdt:P279* wd:Q355304 .
    ?id wdt:P4614* wd:Q51885235  .
    ?id wdt:P131 ?municip .
    ?municip wdt:P131 ?mrc .
    ?mrc wdt:P131 ?region .
    FILTER NOT EXISTS { ?id wdt:P2100 ?ctq }
    SERVICE wikibase:label {
		bd:serviceParam wikibase:language "fr,en" .
	}
} 
ORDER BY ?regionLabel ?mrcLabel ?municipLabel
LIMIT 500

Try it!

Canton du Québec ayant une municipalité en P131 : 22%

# Canton du Québec ayant une municipalité en P131
SELECT ?item ?itemLabel ?itemDescription ?alias ?dtFondation ?km2 ?munLabel ?mrcLabel ?regionLabel ?coord 
WHERE {
    { ?item wdt:P31/wdt:P279* wd:Q23019040 }  
    ?item wdt:P17 wd:Q16 .
    ?item wdt:P131/wdt:P131* ?mun .
    ?mun wdt:P31/wdt:P279* wd:Q3327873 .
    ?mun wdt:P131/wdt:P131* ?mrc .
    ?mrc wdt:P31/wdt:P279* wd:Q204613.
    ?mrc wdt:P131/wdt:P131* ?region .
    ?region wdt:P31/wdt:P279* wd:Q55998242 .
    OPTIONAL {?item skos:altLabel ?alias filter (lang(?alias) = "fr,en")} .
    OPTIONAL {?item wdt:P571 ?dtFondation} .
    OPTIONAL {?item p:P2046 ?area_statement .
              ?area_statement psv:P2046 ?area_node .
              ?area_node wikibase:quantityAmount ?area .  
              ?area_node wikibase:quantityUnit ?unit .
              ?unit wdt:P2370 ?conversionSI . 
              BIND(?area*?conversionSI/1000000 AS ?km2)} .
    OPTIONAL {?item wdt:P625 ?coord}
    SERVICE wikibase:label {
	    bd:serviceParam wikibase:language "fr,en" .
	}
} 
ORDER BY (?regionLabel) 
LIMIT 1800

Try it!

Seigneurie sans identifiant CTQ : 12%

SELECT DISTINCT ?id ?idLabel ?municipLabel ?mrcLabel ?regionLabel  
WHERE 
{
    ?id wdt:P31 wd:Q1550557 .
    ?id wdt:P17 wd:Q16 .
    ?id wdt:P131 ?municip .
    ?municip wdt:P131 ?mrc .
    ?mrc wdt:P131 ?region .
    FILTER NOT EXISTS { ?id wdt:P2100 ?ctq }
    SERVICE wikibase:label {
		bd:serviceParam wikibase:language "fr,en" .
	}
} 
ORDER BY ?regionLabel ?mrcLabel ?municipLabel
LIMIT 200

Try it!

Municipalités sans images : 17%

SELECT DISTINCT ?item ?itemLabel ?mrcLabel 
WHERE {
        {?item wdt:P31*/wdt:P279* wd:Q3327873 }  
	    ?item  wdt:P131 ?mrc;
	           wdt:P625 ?coord;
        MINUS { ?item wdt:P18 [] } . 
        FILTER NOT EXISTS { ?item wdt:P576 ?dissolu}
        FILTER NOT EXISTS { ?item wdt:P582 ?fin }
        SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en" . } 
     }

Try it!

geographic township of Quebec (Q23019040) sans date de fondation : 3%

# Canton du Québec
SELECT ?item ?itemLabel ?itemDescription ?alias ?dtFondation ?km2 ?locLabel ?coord
WHERE {
    { ?item wdt:P31/wdt:P279* wd:Q23019040 }  
    OPTIONAL {?item skos:altLabel ?alias filter (lang(?alias) = "fr,en")} .
    OPTIONAL {?item wdt:P571 ?dtFondation} .
    OPTIONAL {?item p:P2046 ?area_statement .
              ?area_statement psv:P2046 ?area_node .
              ?area_node wikibase:quantityAmount ?area .  
              ?area_node wikibase:quantityUnit ?unit .
              ?unit wdt:P2370 ?conversionSI . 
              BIND(?area*?conversionSI/1000000 AS ?km2)} .
    OPTIONAL {?item wdt:P131 ?loc} .
    FILTER NOT EXISTS { ?item wdt:P571 ?dtFondation }
    SERVICE wikibase:label {
	    bd:serviceParam wikibase:language "fr,en" .
	}
} 
ORDER BY (?regionLabel) 
LIMIT 1800

Try it!

Municipalités sans URL officiel : 1%

SELECT DISTINCT ?municip ?link ?municipLabel ?dateCreation ?superficie ?mrcLabel ?regionLabel  
WHERE 
{   # Municipalités sans URL officiel
    {?municip wdt:P31*/wdt:P279* wd:Q3327873 }  
    ?municip wdt:P31 ?statut .
    ?municip wdt:P131 ?mrc .
    ?mrc wdt:P131 ?region .  
    ?region wdt:P131 wd:Q176 .
    Optional {?municip wdt:P571 ?dateCreation }
    Optional {?municip wdt:P2046 ?superficie }
    Optional {?municip wdt:P856 ?url }
    FILTER NOT EXISTS { ?municip wdt:P856 ?url }
    FILTER NOT EXISTS { ?municip wdt:P576 ?dissolu}
    FILTER NOT EXISTS { ?municip wdt:P582 ?fin }
    FILTER NOT EXISTS { ?municip p:P31 [ pq:P582 ?pqfin ] }
    SERVICE wikibase:label {
		bd:serviceParam wikibase:language "fr,en" .
	}
    OPTIONAL {
            ?link schema:about ?municip .
            ?link schema:isPartOf <https://fr.wikipedia.org/> }
} 
ORDER BY ?regionLabel ?mrcLabel ?municipLabel
LIMIT 1000

Try it!

Municipalités sans date de création : 0%

10 % à renseigner Municipalités sans date de création

Municipalités sans identifiant OSM : 0%

SELECT DISTINCT ?municip ?municipLabel ?statutLabel ?mrcLabel ?regionLabel  
WHERE 
{
    {?municip wdt:P31*/wdt:P279* wd:Q3327873 } UNION {?municip wdt:P31 wd:Q3518810 }
    ?municip wdt:P31 ?statut .
    ?municip wdt:P131 ?mrc .
    ?mrc wdt:P131 ?region .  
    ?region wdt:P131 wd:Q176 .
    Optional {?municip wdt:P402 ?mrc .}
    FILTER NOT EXISTS { ?municip wdt:P402 ?osm }
    FILTER NOT EXISTS { ?municip wdt:P576 ?dissolu}
    FILTER NOT EXISTS { ?municip wdt:P582 ?fin }
    FILTER NOT EXISTS { ?municip p:P31 [ pq:P582 ?pqfin ] }
    SERVICE wikibase:label {
		bd:serviceParam wikibase:language "fr,en" .
	}
} 
ORDER BY ?regionLabel ?mrcLabel ?municipLabel
LIMIT 1000

Try it!

Municipalités sans identifiant CTQ : 0%

Aucune

SELECT DISTINCT ?municip ?municipLabel ?statutLabel ?mrcLabel ?regionLabel  
WHERE 
{
    {?municip wdt:P31*/wdt:P279* wd:Q3327873 } UNION {?municip wdt:P31 wd:Q3518810 }
    ?municip wdt:P31 ?statut .
    ?municip wdt:P131 ?mrc .
    ?mrc wdt:P131 ?region .  
    ?region wdt:P131 wd:Q176 .
    Optional {?municip wdt:P2100 ?mrc .}
    FILTER NOT EXISTS { ?municip wdt:P2100 ?ctq }
    FILTER NOT EXISTS { ?municip wdt:P576 ?dissolu}
    FILTER NOT EXISTS { ?municip wdt:P582 ?fin }
    FILTER NOT EXISTS { ?municip p:P31 [ pq:P582 ?pqfin ] }
    SERVICE wikibase:label {
		bd:serviceParam wikibase:language "fr,en" .
	}
} 
ORDER BY ?regionLabel ?mrcLabel ?municipLabel
LIMIT 1000

Try it!

Municipalités sans identifiant statcan

SELECT DISTINCT ?municip ?link ?municipLabel ?dateCreation ?superficie ?mrcLabel ?regionLabel  
WHERE 
{
    {?municip wdt:P31*/wdt:P279* wd:Q3327873 } UNION {?municip wdt:P31 wd:Q3518810 }
    ?municip wdt:P31 ?statut .
    ?municip wdt:P131 ?mrc .
    ?mrc wdt:P131 ?region .  
    ?region wdt:P131 wd:Q176 .
    Optional {?municip wdt:P3012 ?statscan }
    Optional {?municip wdt:P571 ?dateCreation }
    Optional {?municip wdt:P2046 ?superficie }
    Optional {?municip wdt:P856 ?url }
    FILTER NOT EXISTS { ?municip wdt:P856 ?statscan }
    FILTER NOT EXISTS { ?municip wdt:P576 ?dissolu}
    FILTER NOT EXISTS { ?municip wdt:P582 ?fin }
    FILTER NOT EXISTS { ?municip p:P31 [ pq:P582 ?pqfin ] }
    SERVICE wikibase:label {
		bd:serviceParam wikibase:language "fr,en" .
	}
    OPTIONAL {
            ?link schema:about ?municip .
            ?link schema:isPartOf <https://fr.wikipedia.org/> }
} 
ORDER BY ?regionLabel ?mrcLabel ?municipLabel
LIMIT 2000

Try it!

Notes

Pourquoi et comment participer à Wikipédia et Wikidata.
Conscientisation[1].

WP:fr

Le retrait de la ligne vide avant le RI dans cette modification a pour but de permettre l'affichage de celui-ci dans la la fenêtre popup.
La gouvernance de Wikipédia[2].
Implantation du code de conduite universel, une piste.
Même constat que TigH[3].
Perle.
Perle RSV[4].

To-do

Traduire :
fr:Québec#Politique des affaires sociales et de l'éducation + médecine à deux vitesses[6],[7],[8],[9],[10],[11].

Welcome to Wikidata, YanikB!

Wikidata is a free knowledge base that you can edit! It can be read and edited by humans and machines alike and you can go to any item page now and add to this ever-growing database!

Need some help getting started? Here are some pages you can familiarize yourself with:

Introduction – An introduction to the project.
Wikidata tours – Interactive tutorials to show you how Wikidata works.
Community portal – The portal for community members.
User options – including the 'Babel' extension, to set your language preferences.
Contents – The main help page for editing and using the site.
Project chat – Discussions about the project.
Tools – A collection of user-developed tools to allow for easier completion of some tasks.

Please remember to sign your messages on talk pages by typing four tildes (~~~~); this will automatically insert your username and the date.

If you have any questions, don't hesitate to ask on Project chat. If you want to try out editing, you can use the sandbox to try. Once again, welcome, and I hope you quickly feel comfortable here, and become an active editor for Wikidata.

Best regards!

[1] Gracieuseté de User:TomT0m

[1]

User:YanikB

Ressources

Description du code

Modèles

Nomenclature

Outils

OpenRefine

Avancements

Rivières sur l'île d'Anticosti

Municipalités du Québec sans gentilé

Communautés autochtones au Québec

Rivières du bassin de la baie d'Hudson sans article sur WP:fr

Rivières du bassin de l'Harricana

Rivières du bassin de la Rupert

Rivières du bassin versant de la rivière baie James

Rivières du bassin de la Nottaway

Lac sans drainage basin (P4614)

Rivières du Québec sans longueur

Rivières du bassin de la Baie d'Hudson sans identifiant OSM

Affluents de l'Amazone

Affluents du Missouri

Affluents du Mississippi

Personnalités mortes de la Covid-19 par pays par années

Longueur totale des rivières au Québec (J'ai tracé 75K km sur le résultat)

Rivières du Québec ayant plusieurs mouth of the watercourse (P403)

Tributaires de la baie d'Ungava

Rivières du bassin des Outaouais sans article

Cours d'eau du bassin du lac Saint-Pierre sans crénon

Cours d'eau du bassin du lac Saint-Pierre

Estimation de population 2021 des MRC

Estimation de population 2021 des régions

Chenal au Québec

Affluent de l'estuaire sans identifiant OSM

Maj identifiant OSM

Affluent du Saint-Laurent sans longueur

4 MRC sans URL officiel

Personnalité inhumée au cimetière Mont-Royal‎

Quartiers de référence de Montréal : 98%

Affluents et sous-affluent du Saint-Laurent sans drainage basin (P4614)

Cours d'eau du bassin de l'estuaire du Saint-Laurent sans identifiant CTQ

Canton du Québec ayant une municipalité en P131 : 22%

Seigneurie sans identifiant CTQ : 12%

Municipalités sans images : 17%

geographic township of Quebec (Q23019040) sans date de fondation : 3%

Municipalités sans URL officiel : 1%

Municipalités sans date de création : 0%

Municipalités sans identifiant OSM : 0%

Municipalités sans identifiant CTQ : 0%

Municipalités sans identifiant statcan

Notes

WP:fr

To-do

Navigation menu

Search